The Design and Implementation of the FreeBSD Operating System, Second Edition
Now available: The Design and Implementation of the FreeBSD Operating System (Second Edition)


[ source navigation ] [ diff markup ] [ identifier search ] [ freetext search ] [ file search ] [ list types ] [ track identifier ]

FreeBSD/Linux Kernel Cross Reference
sys/amd64/linux32/linux32_vdso.lds.s

Version: -  FREEBSD  -  FREEBSD-12-STABLE  -  FREEBSD-12-0  -  FREEBSD-11-STABLE  -  FREEBSD-11-2  -  FREEBSD-11-1  -  FREEBSD-11-0  -  FREEBSD-10-STABLE  -  FREEBSD-10-4  -  FREEBSD-10-3  -  FREEBSD-10-2  -  FREEBSD-10-1  -  FREEBSD-10-0  -  FREEBSD-9-STABLE  -  FREEBSD-9-3  -  FREEBSD-9-2  -  FREEBSD-9-1  -  FREEBSD-9-0  -  FREEBSD-8-STABLE  -  FREEBSD-8-4  -  FREEBSD-8-3  -  FREEBSD-8-2  -  FREEBSD-8-1  -  FREEBSD-8-0  -  FREEBSD-7-STABLE  -  FREEBSD-7-4  -  FREEBSD-7-3  -  FREEBSD-7-2  -  FREEBSD-7-1  -  FREEBSD-7-0  -  FREEBSD-6-STABLE  -  FREEBSD-6-4  -  FREEBSD-6-3  -  FREEBSD-6-2  -  FREEBSD-6-1  -  FREEBSD-6-0  -  FREEBSD-5-STABLE  -  FREEBSD-5-5  -  FREEBSD-5-4  -  FREEBSD-5-3  -  FREEBSD-5-2  -  FREEBSD-5-1  -  FREEBSD-5-0  -  FREEBSD-4-STABLE  -  FREEBSD-3-STABLE  -  FREEBSD22  -  linux-2.6  -  linux-2.4.22  -  MK83  -  MK84  -  PLAN9  -  DFBSD  -  NETBSD  -  NETBSD5  -  NETBSD4  -  NETBSD3  -  NETBSD20  -  OPENBSD  -  xnu-517  -  xnu-792  -  xnu-792.6.70  -  xnu-1228  -  xnu-1456.1.26  -  xnu-1699.24.8  -  xnu-2050.18.24  -  OPENSOLARIS  -  minix-3-1-1 
SearchContext: -  none  -  3  -  10 

    1 /*
    2  * Linker script for 32-bit vDSO.
    3  * Copied from Linux kernel arch/x86/vdso/vdso-layout.lds.S
    4  * and arch/x86/vdso/vdso32/vdso32.lds.S
    5  *
    6  * $FreeBSD: stable/12/sys/amd64/linux32/linux32_vdso.lds.s 283410 2015-05-24 15:30:52Z dchagin $
    7  */
    8 
    9 SECTIONS
   10 {
   11         . = . + SIZEOF_HEADERS;
   12 
   13         .hash           : { *(.hash) }                  :text
   14         .gnu.hash       : { *(.gnu.hash) }
   15         .dynsym         : { *(.dynsym) }
   16         .dynstr         : { *(.dynstr) }
   17         .gnu.version    : { *(.gnu.version) }
   18         .gnu.version_d  : { *(.gnu.version_d) }
   19         .gnu.version_r  : { *(.gnu.version_r) }
   20 
   21         .note           : { *(.note.*) }                :text   :note
   22 
   23         .eh_frame_hdr   : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
   24         .eh_frame       : { KEEP (*(.eh_frame)) }       :text
   25 
   26         .dynamic        : { *(.dynamic) }               :text   :dynamic
   27 
   28         .rodata         : { *(.rodata*) }               :text
   29         .data           : {
   30               *(.data*)
   31               *(.sdata*)
   32               *(.got.plt) *(.got)
   33               *(.gnu.linkonce.d.*)
   34               *(.bss*)
   35               *(.dynbss*)
   36               *(.gnu.linkonce.b.*)
   37         }
   38 
   39         .altinstructions        : { *(.altinstructions) }
   40         .altinstr_replacement   : { *(.altinstr_replacement) }
   41 
   42         . = ALIGN(0x100);
   43         .text           : { *(.text*) }                 :text   =0x90909090
   44 }
   45 
   46 PHDRS
   47 {
   48         text            PT_LOAD         FLAGS(5) FILEHDR PHDRS; /* PF_R|PF_X */
   49         dynamic         PT_DYNAMIC      FLAGS(4);               /* PF_R */
   50         note            PT_NOTE         FLAGS(4);               /* PF_R */
   51         eh_frame_hdr    PT_GNU_EH_FRAME;
   52 }
   53 
   54 ENTRY(linux32_vsyscall);
   55 
   56 VERSION
   57 {
   58         LINUX_2.5 {
   59         global:
   60                 linux32_vsyscall;
   61                 linux32_sigcode;
   62                 linux32_rt_sigcode;
   63                 linux_platform;
   64         local: *;
   65         };
   66 }

Cache object: db9c318b9e43e482520d814b2a68324e


[ source navigation ] [ diff markup ] [ identifier search ] [ freetext search ] [ file search ] [ list types ] [ track identifier ]


This page is part of the FreeBSD/Linux Linux Kernel Cross-Reference, and was automatically generated using a modified version of the LXR engine.