FreeBSD/Linux Kernel Cross Reference
sys/conf/ldscript.arm
1 /* $FreeBSD: releng/11.0/sys/conf/ldscript.arm 261227 2014-01-28 09:12:04Z andrew $ */
2 OUTPUT_ARCH(arm)
3 ENTRY(_start)
4
5 SEARCH_DIR(/usr/lib);
6 SECTIONS
7 {
8 /* Read-only sections, merged into text segment: */
9 . = KERNVIRTADDR + SIZEOF_HEADERS;
10 .text :
11 {
12 *(.text)
13 *(.stub)
14 /* .gnu.warning sections are handled specially by elf32.em. */
15 *(.gnu.warning)
16 *(.gnu.linkonce.t*)
17 } =0x9090
18 _etext = .;
19 PROVIDE (etext = .);
20 .fini : { *(.fini) } =0x9090
21 .rodata : { *(.rodata) *(.gnu.linkonce.r*) }
22 .rodata1 : { *(.rodata1) }
23 .interp : { *(.interp) }
24 .hash : { *(.hash) }
25 .dynsym : { *(.dynsym) }
26 .dynstr : { *(.dynstr) }
27 .gnu.version : { *(.gnu.version) }
28 .gnu.version_d : { *(.gnu.version_d) }
29 .gnu.version_r : { *(.gnu.version_r) }
30 .rel.text :
31 { *(.rel.text) *(.rel.gnu.linkonce.t*) }
32 .rela.text :
33 { *(.rela.text) *(.rela.gnu.linkonce.t*) }
34 .rel.data :
35 { *(.rel.data) *(.rel.gnu.linkonce.d*) }
36 .rela.data :
37 { *(.rela.data) *(.rela.gnu.linkonce.d*) }
38 .rel.rodata :
39 { *(.rel.rodata) *(.rel.gnu.linkonce.r*) }
40 .rela.rodata :
41 { *(.rela.rodata) *(.rela.gnu.linkonce.r*) }
42 .rel.got : { *(.rel.got) }
43 .rela.got : { *(.rela.got) }
44 .rel.ctors : { *(.rel.ctors) }
45 .rela.ctors : { *(.rela.ctors) }
46 .rel.dtors : { *(.rel.dtors) }
47 .rela.dtors : { *(.rela.dtors) }
48 .rel.init : { *(.rel.init) }
49 .rela.init : { *(.rela.init) }
50 .rel.fini : { *(.rel.fini) }
51 .rela.fini : { *(.rela.fini) }
52 .rel.bss : { *(.rel.bss) }
53 .rela.bss : { *(.rela.bss) }
54 .rel.plt : { *(.rel.plt) }
55 .rela.plt : { *(.rela.plt) }
56 .init : { *(.init) } =0x9090
57 .plt : { *(.plt) }
58
59 . = ALIGN(4);
60 _extab_start = .;
61 PROVIDE(extab_start = .);
62 .ARM.extab : { *(.ARM.extab) }
63 _extab.end = .;
64 PROVIDE(extab_end = .);
65
66 _exidx_start = .;
67 PROVIDE(exidx_start = .);
68 .ARM.exidx : { *(.ARM.exidx) }
69 _exidx_end = .;
70 PROVIDE(exidx_end = .);
71
72 /* Adjust the address for the data segment. We want to adjust up to
73 the same address within the page on the next page up. */
74 . = ALIGN(0x1000) + (. & (0x1000 - 1)) ;
75 .data :
76 {
77 *(.data)
78 *(.gnu.linkonce.d*)
79 CONSTRUCTORS
80 }
81 .data1 : { *(.data1) }
82 . = ALIGN(32 / 8);
83 _start_ctors = .;
84 PROVIDE (start_ctors = .);
85 .ctors :
86 {
87 *(.ctors)
88 }
89 _stop_ctors = .;
90 PROVIDE (stop_ctors = .);
91 .dtors :
92 {
93 *(.dtors)
94 }
95 .got : { *(.got.plt) *(.got) }
96 .dynamic : { *(.dynamic) }
97 /* We want the small data sections together, so single-instruction offsets
98 can access them all, and initialized data all before uninitialized, so
99 we can shorten the on-disk segment size. */
100 .sdata : { *(.sdata) }
101 _edata = .;
102 PROVIDE (edata = .);
103 __bss_start = .;
104 .sbss : { *(.sbss) *(.scommon) }
105 .bss :
106 {
107 *(.dynbss)
108 *(.bss)
109 *(COMMON)
110 . = ALIGN(32 / 8);
111 _ebss = .;
112 /* A section for the initial page table, it doesn't need to be in the
113 kernel file, however unlike normal .bss entries should not be zeroed
114 out as we use it before the .bss section is cleared. */
115 *(.init_pagetable)
116 }
117 . = ALIGN(32 / 8);
118 _end = . ;
119 PROVIDE (end = .);
120 /* Stabs debugging sections. */
121 .stab 0 : { *(.stab) }
122 .stabstr 0 : { *(.stabstr) }
123 .stab.excl 0 : { *(.stab.excl) }
124 .stab.exclstr 0 : { *(.stab.exclstr) }
125 .stab.index 0 : { *(.stab.index) }
126 .stab.indexstr 0 : { *(.stab.indexstr) }
127 .comment 0 : { *(.comment) }
128 /* DWARF debug sections.
129 Symbols in the DWARF debugging sections are relative to the beginning
130 of the section so we begin them at 0. */
131 /* DWARF 1 */
132 .debug 0 : { *(.debug) }
133 .line 0 : { *(.line) }
134 /* GNU DWARF 1 extensions */
135 .debug_srcinfo 0 : { *(.debug_srcinfo) }
136 .debug_sfnames 0 : { *(.debug_sfnames) }
137 /* DWARF 1.1 and DWARF 2 */
138 .debug_aranges 0 : { *(.debug_aranges) }
139 .debug_pubnames 0 : { *(.debug_pubnames) }
140 /* DWARF 2 */
141 .debug_info 0 : { *(.debug_info) }
142 .debug_abbrev 0 : { *(.debug_abbrev) }
143 .debug_line 0 : { *(.debug_line) }
144 .debug_frame 0 : { *(.debug_frame) }
145 .debug_str 0 : { *(.debug_str) }
146 .debug_loc 0 : { *(.debug_loc) }
147 .debug_macinfo 0 : { *(.debug_macinfo) }
148 /* SGI/MIPS DWARF 2 extensions */
149 .debug_weaknames 0 : { *(.debug_weaknames) }
150 .debug_funcnames 0 : { *(.debug_funcnames) }
151 .debug_typenames 0 : { *(.debug_typenames) }
152 .debug_varnames 0 : { *(.debug_varnames) }
153 /* These must appear regardless of . */
154 }
Cache object: b072d787175cc4547de3d0d84b6f3ff5
|