ldscript.mips.octeon1

Version: - FREEBSD - FREEBSD-13-STABLE - FREEBSD-13-0 - FREEBSD-12-STABLE - FREEBSD-12-0 - FREEBSD-11-STABLE - FREEBSD-11-0 - FREEBSD-10-STABLE - FREEBSD-10-0 - FREEBSD-9-STABLE - FREEBSD-9-0 - FREEBSD-8-STABLE - FREEBSD-8-0 - FREEBSD-7-STABLE - FREEBSD-7-0 - FREEBSD-6-STABLE - FREEBSD-6-0 - FREEBSD-5-STABLE - FREEBSD-5-0 - FREEBSD-4-STABLE - FREEBSD-3-STABLE - FREEBSD22 - l41 - OPENBSD - linux-2.6 - MK84 - PLAN9 - xnu-8792
SearchContext: - none - 3 - 10

    1 /* $FreeBSD$ */
    2 
    3 ENTRY(_start)
    4 
    5 PHDRS {
    6         text PT_LOAD FLAGS(0x7);
    7 }
    8 
    9 SECTIONS {
   10         . = KERNLOADADDR + SIZEOF_HEADERS;
   11 
   12         .text : {
   13                 *(.text)
   14                 etext = .;
   15                 _etext = .;
   16                 . = ALIGN(0x2000);
   17         } : text
   18 
   19         . = ALIGN(0x2000);
   20         .rodata : {
   21                 _fdata = .;
   22                 *(.rodata)
   23                 . = ALIGN(32);
   24         }
   25 
   26         .note.gnu.build-id : {
   27                 PROVIDE (__build_id_start = .);
   28                 *(.note.gnu.build-id)
   29                 PROVIDE (__build_id_end = .);
   30         }
   31         
   32         .data : {
   33                 _rwdata = .;
   34                 *(.data)
   35                 . = ALIGN(32);
   36         }
   37         .plt : { *(.plt) }
   38         _gp = ALIGN(16) + 0x7ff0;
   39         .got : { *(.got.plt) *(.got) }
   40         .dynamic : { *(.dynamic) }
   41 
   42         .sdata : {
   43                 _small_start = .;
   44                 *(.sdata)
   45                 . = ALIGN(32);
   46                 edata = .;
   47                 _edata = .;
   48         } : text
   49 
   50         .sbss : {
   51                 __bss_start = .;
   52                 _fbss = .;
   53                 *(.sbss) *(.scommon)
   54                 _small_end = .;
   55                 . = ALIGN(32);
   56         }
   57 
   58         .bss : {
   59                 *(.bss)
   60                 *(COMMON)
   61                 . = ALIGN(32);
   62                 _end = .;
   63                 end = .;
   64         }
   65 
   66 }

Cache object: da920382b4cb14be3527d2c89a197f04

[ source navigation ] [ diff markup ] [ identifier search ] [ freetext search ] [ file search ] [ list types ] [ track identifier ]

This page is part of the FreeBSD/Linux Linux Kernel Cross-Reference, and was automatically generated using a modified version of the LXR engine.

FreeBSD/Linux Kernel Cross Reference sys/conf/ldscript.mips.octeon1

FreeBSD/Linux Kernel Cross Reference
sys/conf/ldscript.mips.octeon1