devlist2h.awk

Version: - FREEBSD - FREEBSD-13-STABLE - FREEBSD-13-0 - FREEBSD-12-STABLE - FREEBSD-12-0 - FREEBSD-11-STABLE - FREEBSD-11-0 - FREEBSD-10-STABLE - FREEBSD-10-0 - FREEBSD-9-STABLE - FREEBSD-9-0 - FREEBSD-8-STABLE - FREEBSD-8-0 - FREEBSD-7-STABLE - FREEBSD-7-0 - FREEBSD-6-STABLE - FREEBSD-6-0 - FREEBSD-5-STABLE - FREEBSD-5-0 - FREEBSD-4-STABLE - FREEBSD-3-STABLE - FREEBSD22 - l41 - OPENBSD - linux-2.6 - MK84 - PLAN9 - xnu-8792
SearchContext: - none - 3 - 10

    1 #! /usr/bin/awk -f
    2 #       $NetBSD: devlist2h.awk,v 1.8 2003/12/15 07:32:21 jmc Exp $
    3 #
    4 # Copyright (c) 1995, 1996 Christopher G. Demetriou
    5 # All rights reserved.
    6 #
    7 # Redistribution and use in source and binary forms, with or without
    8 # modification, are permitted provided that the following conditions
    9 # are met:
   10 # 1. Redistributions of source code must retain the above copyright
   11 #    notice, this list of conditions and the following disclaimer.
   12 # 2. Redistributions in binary form must reproduce the above copyright
   13 #    notice, this list of conditions and the following disclaimer in the
   14 #    documentation and/or other materials provided with the distribution.
   15 # 3. All advertising materials mentioning features or use of this software
   16 #    must display the following acknowledgement:
   17 #      This product includes software developed by Christopher G. Demetriou.
   18 # 4. The name of the author may not be used to endorse or promote products
   19 #    derived from this software without specific prior written permission
   20 #
   21 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
   22 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
   23 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
   24 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
   25 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
   26 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
   27 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
   28 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
   29 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
   30 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
   31 #
   32 BEGIN {
   33         nproducts = nvendors = blanklines = 0
   34         dfile="pcidevs_data.h"
   35         hfile="pcidevs.h"
   36 }
   37 NR == 1 {
   38         VERSION = $0
   39         gsub("\\$", "", VERSION)
   40 
   41         printf("/*\t$NetBSD" "$\t*/\n\n") > dfile
   42         printf("/*\n") > dfile
   43         printf(" * THIS FILE AUTOMATICALLY GENERATED.  DO NOT EDIT.\n") \
   44             > dfile
   45         printf(" *\n") > dfile
   46         printf(" * generated from:\n") > dfile
   47         printf(" *\t%s\n", VERSION) > dfile
   48         printf(" */\n") > dfile
   49 
   50         printf("/*\t$NetBSD" "$\t*/\n\n") > hfile
   51         printf("/*\n") > hfile
   52         printf(" * THIS FILE AUTOMATICALLY GENERATED.  DO NOT EDIT.\n") \
   53             > hfile
   54         printf(" *\n") > hfile
   55         printf(" * generated from:\n") > hfile
   56         printf(" *\t%s\n", VERSION) > hfile
   57         printf(" */\n") > hfile
   58 
   59         next
   60 }
   61 NF > 0 && $1 == "vendor" {
   62         nvendors++
   63 
   64         vendorindex[$2] = nvendors;             # record index for this name, for later.
   65         vendors[nvendors, 1] = $2;              # name
   66         vendors[nvendors, 2] = $3;              # id
   67         printf("#define\tPCI_VENDOR_%s\t%s\t", vendors[nvendors, 1],
   68             vendors[nvendors, 2]) > hfile
   69 
   70         i = 3; f = 4;
   71 
   72         # comments
   73         ocomment = oparen = 0
   74         if (f <= NF) {
   75                 printf("\t/* ") > hfile
   76                 ocomment = 1;
   77         }
   78         while (f <= NF) {
   79                 if ($f == "#") {
   80                         printf("(") > hfile
   81                         oparen = 1
   82                         f++
   83                         continue
   84                 }
   85                 if (oparen) {
   86                         printf("%s", $f) > hfile
   87                         if (f < NF)
   88                                 printf(" ") > hfile
   89                         f++
   90                         continue
   91                 }
   92                 vendors[nvendors, i] = $f
   93                 printf("%s", vendors[nvendors, i]) > hfile
   94                 if (f < NF)
   95                         printf(" ") > hfile
   96                 i++; f++;
   97         }
   98         if (oparen)
   99                 printf(")") > hfile
  100         if (ocomment)
  101                 printf(" */") > hfile
  102         printf("\n") > hfile
  103 
  104         next
  105 }
  106 NF > 0 && $1 == "product" {
  107         nproducts++
  108 
  109         products[nproducts, 1] = $2;            # vendor name
  110         products[nproducts, 2] = $3;            # product id
  111         products[nproducts, 3] = $4;            # id
  112         printf("#define\tPCI_PRODUCT_%s_%s\t%s\t", products[nproducts, 1],
  113             products[nproducts, 2], products[nproducts, 3]) > hfile
  114 
  115         i=4; f = 5;
  116 
  117         # comments
  118         ocomment = oparen = 0
  119         if (f <= NF) {
  120                 printf("\t/* ") > hfile
  121                 ocomment = 1;
  122         }
  123         while (f <= NF) {
  124                 if ($f == "#") {
  125                         printf("(") > hfile
  126                         oparen = 1
  127                         f++
  128                         continue
  129                 }
  130                 if (oparen) {
  131                         printf("%s", $f) > hfile
  132                         if (f < NF)
  133                                 printf(" ") > hfile
  134                         f++
  135                         continue
  136                 }
  137                 products[nproducts, i] = $f
  138                 printf("%s", products[nproducts, i]) > hfile
  139                 if (f < NF)
  140                         printf(" ") > hfile
  141                 i++; f++;
  142         }
  143         if (oparen)
  144                 printf(")") > hfile
  145         if (ocomment)
  146                 printf(" */") > hfile
  147         printf("\n") > hfile
  148 
  149         next
  150 }
  151 {
  152         if ($0 == "")
  153                 blanklines++
  154         print $0 > hfile
  155         if (blanklines < 2)
  156                 print $0 > dfile
  157 }
  158 END {
  159         # print out the match tables
  160 
  161         printf("\n") > dfile
  162 
  163         printf("const struct pci_knowndev pci_knowndevs[] = {\n") > dfile
  164         for (i = 1; i <= nproducts; i++) {
  165                 printf("\t{\n") > dfile
  166                 printf("\t    PCI_VENDOR_%s, PCI_PRODUCT_%s_%s,\n",
  167                     products[i, 1], products[i, 1], products[i, 2]) \
  168                     > dfile
  169                 printf("\t    ") > dfile
  170                 printf("0") > dfile
  171                 printf(",\n") > dfile
  172 
  173                 vendi = vendorindex[products[i, 1]];
  174                 printf("\t    \"") > dfile
  175                 j = 3;
  176                 needspace = 0;
  177                 while ((vendi, j) in vendors) {
  178                         if (needspace)
  179                                 printf(" ") > dfile
  180                         printf("%s", vendors[vendi, j]) > dfile
  181                         needspace = 1
  182                         j++
  183                 }
  184                 printf("\",\n") > dfile
  185 
  186                 printf("\t    \"") > dfile
  187                 j = 4;
  188                 needspace = 0;
  189                 while ((i, j) in products) {
  190                         if (needspace)
  191                                 printf(" ") > dfile
  192                         printf("%s", products[i, j]) > dfile
  193                         needspace = 1
  194                         j++
  195                 }
  196                 printf("\",\n") > dfile
  197                 printf("\t},\n") > dfile
  198         }
  199         for (i = 1; i <= nvendors; i++) {
  200                 printf("\t{\n") > dfile
  201                 printf("\t    PCI_VENDOR_%s, 0,\n", vendors[i, 1]) \
  202                     > dfile
  203                 printf("\t    PCI_KNOWNDEV_NOPROD,\n") \
  204                     > dfile
  205                 printf("\t    \"") > dfile
  206                 j = 3;
  207                 needspace = 0;
  208                 while ((i, j) in vendors) {
  209                         if (needspace)
  210                                 printf(" ") > dfile
  211                         printf("%s", vendors[i, j]) > dfile
  212                         needspace = 1
  213                         j++
  214                 }
  215                 printf("\",\n") > dfile
  216                 printf("\t    NULL,\n") > dfile
  217                 printf("\t},\n") > dfile
  218         }
  219         printf("\t{ 0, 0, 0, NULL, NULL, }\n") > dfile
  220         printf("};\n") > dfile
  221         close(dfile)
  222         close(hfile)
  223 }

Cache object: d0570c4fb383d6c60dfd3e2e068c2a9e

[ source navigation ] [ diff markup ] [ identifier search ] [ freetext search ] [ file search ] [ list types ] [ track identifier ]

This page is part of the FreeBSD/Linux Linux Kernel Cross-Reference, and was automatically generated using a modified version of the LXR engine.

FreeBSD/Linux Kernel Cross Reference sys/dev/pci/devlist2h.awk

FreeBSD/Linux Kernel Cross Reference
sys/dev/pci/devlist2h.awk