1 /*-
2 * Copyright (c) 1989, 1990 William F. Jolitz.
3 * Copyright (c) 1990 The Regents of the University of California.
4 * Copyright (c) 2007 The FreeBSD Foundation
5 * All rights reserved.
6 *
7 * Portions of this software were developed by A. Joseph Koshy under
8 * sponsorship from the FreeBSD Foundation and Google, Inc.
9 *
10 * Redistribution and use in source and binary forms, with or without
11 * modification, are permitted provided that the following conditions
12 * are met:
13 * 1. Redistributions of source code must retain the above copyright
14 * notice, this list of conditions and the following disclaimer.
15 * 2. Redistributions in binary form must reproduce the above copyright
16 * notice, this list of conditions and the following disclaimer in the
17 * documentation and/or other materials provided with the distribution.
18 * 4. Neither the name of the University nor the names of its contributors
19 * may be used to endorse or promote products derived from this software
20 * without specific prior written permission.
21 *
22 * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
23 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
24 * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
25 * ARE DISCLAIMED. IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
26 * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
27 * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
28 * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
29 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
30 * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
31 * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
32 * SUCH DAMAGE.
33 *
34 * $FreeBSD: releng/10.4/sys/i386/i386/exception.s 322755 2017-08-21 15:44:57Z kib $
35 */
36
37 #include "opt_apic.h"
38 #include "opt_atpic.h"
39 #include "opt_hwpmc_hooks.h"
40 #include "opt_kdtrace.h"
41 #include "opt_npx.h"
42
43 #include <machine/asmacros.h>
44 #include <machine/psl.h>
45 #include <machine/trap.h>
46
47 #include "assym.s"
48
49 #define SEL_RPL_MASK 0x0003
50 #define GSEL_KPL 0x0020 /* GSEL(GCODE_SEL, SEL_KPL) */
51
52 #ifdef KDTRACE_HOOKS
53 .bss
54 .globl dtrace_invop_jump_addr
55 .align 4
56 .type dtrace_invop_jump_addr, @object
57 .size dtrace_invop_jump_addr, 4
58 dtrace_invop_jump_addr:
59 .zero 4
60 .globl dtrace_invop_calltrap_addr
61 .align 4
62 .type dtrace_invop_calltrap_addr, @object
63 .size dtrace_invop_calltrap_addr, 4
64 dtrace_invop_calltrap_addr:
65 .zero 8
66 #endif
67 .text
68 #ifdef HWPMC_HOOKS
69 ENTRY(start_exceptions)
70 #endif
71 /*****************************************************************************/
72 /* Trap handling */
73 /*****************************************************************************/
74 /*
75 * Trap and fault vector routines.
76 *
77 * Most traps are 'trap gates', SDT_SYS386TGT. A trap gate pushes state on
78 * the stack that mostly looks like an interrupt, but does not disable
79 * interrupts. A few of the traps we are use are interrupt gates,
80 * SDT_SYS386IGT, which are nearly the same thing except interrupts are
81 * disabled on entry.
82 *
83 * The cpu will push a certain amount of state onto the kernel stack for
84 * the current process. The amount of state depends on the type of trap
85 * and whether the trap crossed rings or not. See i386/include/frame.h.
86 * At the very least the current EFLAGS (status register, which includes
87 * the interrupt disable state prior to the trap), the code segment register,
88 * and the return instruction pointer are pushed by the cpu. The cpu
89 * will also push an 'error' code for certain traps. We push a dummy
90 * error code for those traps where the cpu doesn't in order to maintain
91 * a consistent frame. We also push a contrived 'trap number'.
92 *
93 * The cpu does not push the general registers, we must do that, and we
94 * must restore them prior to calling 'iret'. The cpu adjusts the %cs and
95 * %ss segment registers, but does not mess with %ds, %es, or %fs. Thus we
96 * must load them with appropriate values for supervisor mode operation.
97 */
98
99 MCOUNT_LABEL(user)
100 MCOUNT_LABEL(btrap)
101
102 #define TRAP(a) pushl $(a) ; jmp alltraps
103
104 IDTVEC(div)
105 pushl $0; TRAP(T_DIVIDE)
106 IDTVEC(dbg)
107 pushl $0; TRAP(T_TRCTRAP)
108 IDTVEC(nmi)
109 pushl $0; TRAP(T_NMI)
110 IDTVEC(bpt)
111 pushl $0; TRAP(T_BPTFLT)
112 IDTVEC(dtrace_ret)
113 pushl $0; TRAP(T_DTRACE_RET)
114 IDTVEC(ofl)
115 pushl $0; TRAP(T_OFLOW)
116 IDTVEC(bnd)
117 pushl $0; TRAP(T_BOUND)
118 #ifndef KDTRACE_HOOKS
119 IDTVEC(ill)
120 pushl $0; TRAP(T_PRIVINFLT)
121 #endif
122 IDTVEC(dna)
123 pushl $0; TRAP(T_DNA)
124 IDTVEC(fpusegm)
125 pushl $0; TRAP(T_FPOPFLT)
126 IDTVEC(tss)
127 TRAP(T_TSSFLT)
128 IDTVEC(missing)
129 TRAP(T_SEGNPFLT)
130 IDTVEC(stk)
131 TRAP(T_STKFLT)
132 IDTVEC(prot)
133 TRAP(T_PROTFLT)
134 IDTVEC(page)
135 TRAP(T_PAGEFLT)
136 IDTVEC(mchk)
137 pushl $0; TRAP(T_MCHK)
138 IDTVEC(rsvd)
139 pushl $0; TRAP(T_RESERVED)
140 IDTVEC(fpu)
141 pushl $0; TRAP(T_ARITHTRAP)
142 IDTVEC(align)
143 TRAP(T_ALIGNFLT)
144 IDTVEC(xmm)
145 pushl $0; TRAP(T_XMMFLT)
146
147 /*
148 * All traps except ones for syscalls jump to alltraps. If
149 * interrupts were enabled when the trap occurred, then interrupts
150 * are enabled now if the trap was through a trap gate, else
151 * disabled if the trap was through an interrupt gate. Note that
152 * int0x80_syscall is a trap gate. Interrupt gates are used by
153 * page faults, non-maskable interrupts, debug and breakpoint
154 * exceptions.
155 */
156 SUPERALIGN_TEXT
157 .globl alltraps
158 .type alltraps,@function
159 alltraps:
160 pushal
161 pushl $0
162 movw %ds,(%esp)
163 pushl $0
164 movw %es,(%esp)
165 pushl $0
166 movw %fs,(%esp)
167 alltraps_with_regs_pushed:
168 SET_KERNEL_SREGS
169 cld
170 FAKE_MCOUNT(TF_EIP(%esp))
171 calltrap:
172 pushl %esp
173 call trap
174 add $4, %esp
175
176 /*
177 * Return via doreti to handle ASTs.
178 */
179 MEXITCOUNT
180 jmp doreti
181
182 /*
183 * Privileged instruction fault.
184 */
185 #ifdef KDTRACE_HOOKS
186 SUPERALIGN_TEXT
187 IDTVEC(ill)
188 /*
189 * Check if a DTrace hook is registered. The default (data) segment
190 * cannot be used for this since %ds is not known good until we
191 * verify that the entry was from kernel mode.
192 */
193 cmpl $0,%ss:dtrace_invop_jump_addr
194 je norm_ill
195
196 /*
197 * Check if this is a user fault. If so, just handle it as a normal
198 * trap.
199 */
200 cmpl $GSEL_KPL, 4(%esp) /* Check the code segment */
201 jne norm_ill
202 testl $PSL_VM, 8(%esp) /* and vm86 mode. */
203 jnz norm_ill
204
205 /*
206 * This is a kernel instruction fault that might have been caused
207 * by a DTrace provider.
208 */
209 pushal
210 cld
211
212 /*
213 * Set our jump address for the jump back in the event that
214 * the exception wasn't caused by DTrace at all.
215 */
216 movl $norm_ill, dtrace_invop_calltrap_addr
217
218 /* Jump to the code hooked in by DTrace. */
219 jmpl *dtrace_invop_jump_addr
220
221 /*
222 * Process the instruction fault in the normal way.
223 */
224 norm_ill:
225 pushl $0
226 TRAP(T_PRIVINFLT)
227 #endif
228
229 /*
230 * Call gate entry for syscalls (lcall 7,0).
231 * This is used by FreeBSD 1.x a.out executables and "old" NetBSD executables.
232 *
233 * The intersegment call has been set up to specify one dummy parameter.
234 * This leaves a place to put eflags so that the call frame can be
235 * converted to a trap frame. Note that the eflags is (semi-)bogusly
236 * pushed into (what will be) tf_err and then copied later into the
237 * final spot. It has to be done this way because esp can't be just
238 * temporarily altered for the pushfl - an interrupt might come in
239 * and clobber the saved cs/eip.
240 */
241 SUPERALIGN_TEXT
242 IDTVEC(lcall_syscall)
243 pushfl /* save eflags */
244 popl 8(%esp) /* shuffle into tf_eflags */
245 pushl $7 /* sizeof "lcall 7,0" */
246 pushl $0 /* tf_trapno */
247 pushal
248 pushl $0
249 movw %ds,(%esp)
250 pushl $0
251 movw %es,(%esp)
252 pushl $0
253 movw %fs,(%esp)
254 SET_KERNEL_SREGS
255 cld
256 FAKE_MCOUNT(TF_EIP(%esp))
257 pushl %esp
258 call syscall
259 add $4, %esp
260 MEXITCOUNT
261 jmp doreti
262
263 /*
264 * Trap gate entry for syscalls (int 0x80).
265 * This is used by FreeBSD ELF executables, "new" NetBSD executables, and all
266 * Linux executables.
267 *
268 * Even though the name says 'int0x80', this is actually a trap gate, not an
269 * interrupt gate. Thus interrupts are enabled on entry just as they are for
270 * a normal syscall.
271 */
272 SUPERALIGN_TEXT
273 IDTVEC(int0x80_syscall)
274 pushl $2 /* sizeof "int 0x80" */
275 pushl $0 /* tf_trapno */
276 pushal
277 pushl $0
278 movw %ds,(%esp)
279 pushl $0
280 movw %es,(%esp)
281 pushl $0
282 movw %fs,(%esp)
283 SET_KERNEL_SREGS
284 cld
285 FAKE_MCOUNT(TF_EIP(%esp))
286 pushl %esp
287 call syscall
288 add $4, %esp
289 MEXITCOUNT
290 jmp doreti
291
292 ENTRY(fork_trampoline)
293 pushl %esp /* trapframe pointer */
294 pushl %ebx /* arg1 */
295 pushl %esi /* function */
296 call fork_exit
297 addl $12,%esp
298 /* cut from syscall */
299
300 /*
301 * Return via doreti to handle ASTs.
302 */
303 MEXITCOUNT
304 jmp doreti
305
306
307 /*
308 * To efficiently implement classification of trap and interrupt handlers
309 * for profiling, there must be only trap handlers between the labels btrap
310 * and bintr, and only interrupt handlers between the labels bintr and
311 * eintr. This is implemented (partly) by including files that contain
312 * some of the handlers. Before including the files, set up a normal asm
313 * environment so that the included files doen't need to know that they are
314 * included.
315 */
316
317 .data
318 .p2align 4
319 .text
320 SUPERALIGN_TEXT
321 MCOUNT_LABEL(bintr)
322
323 #ifdef DEV_ATPIC
324 #include <i386/i386/atpic_vector.s>
325 #endif
326
327 #if defined(DEV_APIC) && defined(DEV_ATPIC)
328 .data
329 .p2align 4
330 .text
331 SUPERALIGN_TEXT
332 #endif
333
334 #ifdef DEV_APIC
335 #include <i386/i386/apic_vector.s>
336 #endif
337
338 .data
339 .p2align 4
340 .text
341 SUPERALIGN_TEXT
342 #include <i386/i386/vm86bios.s>
343
344 .text
345 MCOUNT_LABEL(eintr)
346
347 /*
348 * void doreti(struct trapframe)
349 *
350 * Handle return from interrupts, traps and syscalls.
351 */
352 .text
353 SUPERALIGN_TEXT
354 .type doreti,@function
355 .globl doreti
356 doreti:
357 FAKE_MCOUNT($bintr) /* init "from" bintr -> doreti */
358 doreti_next:
359 /*
360 * Check if ASTs can be handled now. ASTs cannot be safely
361 * processed when returning from an NMI.
362 */
363 cmpb $T_NMI,TF_TRAPNO(%esp)
364 #ifdef HWPMC_HOOKS
365 je doreti_nmi
366 #else
367 je doreti_exit
368 #endif
369 /*
370 * PSL_VM must be checked first since segment registers only
371 * have an RPL in non-VM86 mode.
372 * ASTs can not be handled now if we are in a vm86 call.
373 */
374 testl $PSL_VM,TF_EFLAGS(%esp)
375 jz doreti_notvm86
376 movl PCPU(CURPCB),%ecx
377 testl $PCB_VM86CALL,PCB_FLAGS(%ecx)
378 jz doreti_ast
379 jmp doreti_exit
380
381 doreti_notvm86:
382 testb $SEL_RPL_MASK,TF_CS(%esp) /* are we returning to user mode? */
383 jz doreti_exit /* can't handle ASTs now if not */
384
385 doreti_ast:
386 /*
387 * Check for ASTs atomically with returning. Disabling CPU
388 * interrupts provides sufficient locking even in the SMP case,
389 * since we will be informed of any new ASTs by an IPI.
390 */
391 cli
392 movl PCPU(CURTHREAD),%eax
393 testl $TDF_ASTPENDING | TDF_NEEDRESCHED,TD_FLAGS(%eax)
394 je doreti_exit
395 sti
396 pushl %esp /* pass a pointer to the trapframe */
397 call ast
398 add $4,%esp
399 jmp doreti_ast
400
401 /*
402 * doreti_exit: pop registers, iret.
403 *
404 * The segment register pop is a special case, since it may
405 * fault if (for example) a sigreturn specifies bad segment
406 * registers. The fault is handled in trap.c.
407 */
408 doreti_exit:
409 MEXITCOUNT
410
411 .globl doreti_popl_fs
412 doreti_popl_fs:
413 popl %fs
414 .globl doreti_popl_es
415 doreti_popl_es:
416 popl %es
417 .globl doreti_popl_ds
418 doreti_popl_ds:
419 popl %ds
420 popal
421 addl $8,%esp
422 .globl doreti_iret
423 doreti_iret:
424 iret
425
426 /*
427 * doreti_iret_fault and friends. Alternative return code for
428 * the case where we get a fault in the doreti_exit code
429 * above. trap() (i386/i386/trap.c) catches this specific
430 * case, sends the process a signal and continues in the
431 * corresponding place in the code below.
432 */
433 ALIGN_TEXT
434 .globl doreti_iret_fault
435 doreti_iret_fault:
436 subl $8,%esp
437 pushal
438 pushl $0
439 movw %ds,(%esp)
440 .globl doreti_popl_ds_fault
441 doreti_popl_ds_fault:
442 pushl $0
443 movw %es,(%esp)
444 .globl doreti_popl_es_fault
445 doreti_popl_es_fault:
446 pushl $0
447 movw %fs,(%esp)
448 .globl doreti_popl_fs_fault
449 doreti_popl_fs_fault:
450 sti
451 movl $0,TF_ERR(%esp) /* XXX should be the error code */
452 movl $T_PROTFLT,TF_TRAPNO(%esp)
453 jmp alltraps_with_regs_pushed
454 #ifdef HWPMC_HOOKS
455 doreti_nmi:
456 /*
457 * Since we are returning from an NMI, check if the current trap
458 * was from user mode and if so whether the current thread
459 * needs a user call chain capture.
460 */
461 testb $SEL_RPL_MASK,TF_CS(%esp)
462 jz doreti_exit
463 movl PCPU(CURTHREAD),%eax /* curthread present? */
464 orl %eax,%eax
465 jz doreti_exit
466 testl $TDP_CALLCHAIN,TD_PFLAGS(%eax) /* flagged for capture? */
467 jz doreti_exit
468 /*
469 * Take the processor out of NMI mode by executing a fake "iret".
470 */
471 pushfl
472 pushl %cs
473 pushl $outofnmi
474 iret
475 outofnmi:
476 /*
477 * Call the callchain capture hook after turning interrupts back on.
478 */
479 movl pmc_hook,%ecx
480 orl %ecx,%ecx
481 jz doreti_exit
482 pushl %esp /* frame pointer */
483 pushl $PMC_FN_USER_CALLCHAIN /* command */
484 movl PCPU(CURTHREAD),%eax
485 pushl %eax /* curthread */
486 sti
487 call *%ecx
488 addl $12,%esp
489 jmp doreti_ast
490 ENTRY(end_exceptions)
491 #endif
Cache object: 0a2036606d0de3f3b2bca5805d4b245d
|