The Design and Implementation of the FreeBSD Operating System, Second Edition
Now available: The Design and Implementation of the FreeBSD Operating System (Second Edition)


[ source navigation ] [ diff markup ] [ identifier search ] [ freetext search ] [ file search ] [ list types ] [ track identifier ]

FreeBSD/Linux Kernel Cross Reference
sys/i386/i386/swtch.s

Version: -  FREEBSD  -  FREEBSD-12-STABLE  -  FREEBSD-12-0  -  FREEBSD-11-STABLE  -  FREEBSD-11-2  -  FREEBSD-11-1  -  FREEBSD-11-0  -  FREEBSD-10-STABLE  -  FREEBSD-10-4  -  FREEBSD-10-3  -  FREEBSD-10-2  -  FREEBSD-10-1  -  FREEBSD-10-0  -  FREEBSD-9-STABLE  -  FREEBSD-9-3  -  FREEBSD-9-2  -  FREEBSD-9-1  -  FREEBSD-9-0  -  FREEBSD-8-STABLE  -  FREEBSD-8-4  -  FREEBSD-8-3  -  FREEBSD-8-2  -  FREEBSD-8-1  -  FREEBSD-8-0  -  FREEBSD-7-STABLE  -  FREEBSD-7-4  -  FREEBSD-7-3  -  FREEBSD-7-2  -  FREEBSD-7-1  -  FREEBSD-7-0  -  FREEBSD-6-STABLE  -  FREEBSD-6-4  -  FREEBSD-6-3  -  FREEBSD-6-2  -  FREEBSD-6-1  -  FREEBSD-6-0  -  FREEBSD-5-STABLE  -  FREEBSD-5-5  -  FREEBSD-5-4  -  FREEBSD-5-3  -  FREEBSD-5-2  -  FREEBSD-5-1  -  FREEBSD-5-0  -  FREEBSD-4-STABLE  -  FREEBSD-3-STABLE  -  FREEBSD22  -  linux-2.6  -  linux-2.4.22  -  MK83  -  MK84  -  PLAN9  -  DFBSD  -  NETBSD  -  NETBSD5  -  NETBSD4  -  NETBSD3  -  NETBSD20  -  OPENBSD  -  xnu-517  -  xnu-792  -  xnu-792.6.70  -  xnu-1228  -  xnu-1456.1.26  -  xnu-1699.24.8  -  xnu-2050.18.24  -  OPENSOLARIS  -  minix-3-1-1 
SearchContext: -  none  -  3  -  10 

    1 /*-
    2  * Copyright (c) 1990 The Regents of the University of California.
    3  * All rights reserved.
    4  *
    5  * This code is derived from software contributed to Berkeley by
    6  * William Jolitz.
    7  *
    8  * Redistribution and use in source and binary forms, with or without
    9  * modification, are permitted provided that the following conditions
   10  * are met:
   11  * 1. Redistributions of source code must retain the above copyright
   12  *    notice, this list of conditions and the following disclaimer.
   13  * 2. Redistributions in binary form must reproduce the above copyright
   14  *    notice, this list of conditions and the following disclaimer in the
   15  *    documentation and/or other materials provided with the distribution.
   16  * 4. Neither the name of the University nor the names of its contributors
   17  *    may be used to endorse or promote products derived from this software
   18  *    without specific prior written permission.
   19  *
   20  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
   21  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
   22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
   23  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
   24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
   25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
   26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
   27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
   28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
   29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
   30  * SUCH DAMAGE.
   31  *
   32  * $FreeBSD: releng/11.2/sys/i386/i386/swtch.s 335196 2018-06-15 13:21:37Z kib $
   33  */
   34 
   35 #include "opt_sched.h"
   36 
   37 #include <machine/asmacros.h>
   38 
   39 #include "assym.s"
   40 
   41 #if defined(SMP) && defined(SCHED_ULE)
   42 #define SETOP           xchgl
   43 #define BLOCK_SPIN(reg)                                                 \
   44                 movl            $blocked_lock,%eax ;                    \
   45         100: ;                                                          \
   46                 lock ;                                                  \
   47                 cmpxchgl        %eax,TD_LOCK(reg) ;                     \
   48                 jne             101f ;                                  \
   49                 pause ;                                                 \
   50                 jmp             100b ;                                  \
   51         101:
   52 #else
   53 #define SETOP           movl
   54 #define BLOCK_SPIN(reg)
   55 #endif
   56 
   57 /*****************************************************************************/
   58 /* Scheduling                                                                */
   59 /*****************************************************************************/
   60 
   61         .text
   62 
   63 /*
   64  * cpu_throw()
   65  *
   66  * This is the second half of cpu_switch(). It is used when the current
   67  * thread is either a dummy or slated to die, and we no longer care
   68  * about its state.  This is only a slight optimization and is probably
   69  * not worth it anymore.  Note that we need to clear the pm_active bits so
   70  * we do need the old proc if it still exists.
   71  * 0(%esp) = ret
   72  * 4(%esp) = oldtd
   73  * 8(%esp) = newtd
   74  */
   75 ENTRY(cpu_throw)
   76         movl    PCPU(CPUID), %esi
   77         movl    4(%esp),%ecx                    /* Old thread */
   78         testl   %ecx,%ecx                       /* no thread? */
   79         jz      1f
   80         /* release bit from old pm_active */
   81         movl    PCPU(CURPMAP), %ebx
   82 #ifdef SMP
   83         lock
   84 #endif
   85         btrl    %esi, PM_ACTIVE(%ebx)           /* clear old */
   86 1:
   87         movl    8(%esp),%ecx                    /* New thread */
   88         movl    TD_PCB(%ecx),%edx
   89         movl    PCB_CR3(%edx),%eax
   90         movl    %eax,%cr3
   91         /* set bit in new pm_active */
   92         movl    TD_PROC(%ecx),%eax
   93         movl    P_VMSPACE(%eax), %ebx
   94         addl    $VM_PMAP, %ebx
   95         movl    %ebx, PCPU(CURPMAP)
   96 #ifdef SMP
   97         lock
   98 #endif
   99         btsl    %esi, PM_ACTIVE(%ebx)           /* set new */
  100         jmp     sw1
  101 END(cpu_throw)
  102 
  103 /*
  104  * cpu_switch(old, new)
  105  *
  106  * Save the current thread state, then select the next thread to run
  107  * and load its state.
  108  * 0(%esp) = ret
  109  * 4(%esp) = oldtd
  110  * 8(%esp) = newtd
  111  * 12(%esp) = newlock
  112  */
  113 ENTRY(cpu_switch)
  114 
  115         /* Switch to new thread.  First, save context. */
  116         movl    4(%esp),%ecx
  117 
  118 #ifdef INVARIANTS
  119         testl   %ecx,%ecx                       /* no thread? */
  120         jz      badsw2                          /* no, panic */
  121 #endif
  122 
  123         movl    TD_PCB(%ecx),%edx
  124 
  125         movl    (%esp),%eax                     /* Hardware registers */
  126         movl    %eax,PCB_EIP(%edx)
  127         movl    %ebx,PCB_EBX(%edx)
  128         movl    %esp,PCB_ESP(%edx)
  129         movl    %ebp,PCB_EBP(%edx)
  130         movl    %esi,PCB_ESI(%edx)
  131         movl    %edi,PCB_EDI(%edx)
  132         mov     %gs,PCB_GS(%edx)
  133         pushfl                                  /* PSL */
  134         popl    PCB_PSL(%edx)
  135         /* Test if debug registers should be saved. */
  136         testl   $PCB_DBREGS,PCB_FLAGS(%edx)
  137         jz      1f                              /* no, skip over */
  138         movl    %dr7,%eax                       /* yes, do the save */
  139         movl    %eax,PCB_DR7(%edx)
  140         andl    $0x0000fc00, %eax               /* disable all watchpoints */
  141         movl    %eax,%dr7
  142         movl    %dr6,%eax
  143         movl    %eax,PCB_DR6(%edx)
  144         movl    %dr3,%eax
  145         movl    %eax,PCB_DR3(%edx)
  146         movl    %dr2,%eax
  147         movl    %eax,PCB_DR2(%edx)
  148         movl    %dr1,%eax
  149         movl    %eax,PCB_DR1(%edx)
  150         movl    %dr0,%eax
  151         movl    %eax,PCB_DR0(%edx)
  152 1:
  153 
  154         /* have we used fp, and need a save? */
  155         cmpl    %ecx,PCPU(FPCURTHREAD)
  156         jne     1f
  157         pushl   PCB_SAVEFPU(%edx)               /* h/w bugs make saving complicated */
  158         call    npxsave                         /* do it in a big C function */
  159         popl    %eax
  160 1:
  161 
  162         /* Save is done.  Now fire up new thread. Leave old vmspace. */
  163         movl    4(%esp),%edi
  164         movl    8(%esp),%ecx                    /* New thread */
  165         movl    12(%esp),%esi                   /* New lock */
  166 #ifdef INVARIANTS
  167         testl   %ecx,%ecx                       /* no thread? */
  168         jz      badsw3                          /* no, panic */
  169 #endif
  170         movl    TD_PCB(%ecx),%edx
  171 
  172         /* switch address space */
  173         movl    PCB_CR3(%edx),%eax
  174         movl    %cr3,%ebx                       /* The same address space? */
  175         cmpl    %ebx,%eax
  176         je      sw0
  177         movl    %eax,%cr3                       /* new address space */
  178         movl    %esi,%eax
  179         movl    PCPU(CPUID),%esi
  180         SETOP   %eax,TD_LOCK(%edi)              /* Switchout td_lock */
  181 
  182         /* Release bit from old pmap->pm_active */
  183         movl    PCPU(CURPMAP), %ebx
  184 #ifdef SMP
  185         lock
  186 #endif
  187         btrl    %esi, PM_ACTIVE(%ebx)           /* clear old */
  188 
  189         /* Set bit in new pmap->pm_active */
  190         movl    TD_PROC(%ecx),%eax              /* newproc */
  191         movl    P_VMSPACE(%eax), %ebx
  192         addl    $VM_PMAP, %ebx
  193         movl    %ebx, PCPU(CURPMAP)
  194 #ifdef SMP
  195         lock
  196 #endif
  197         btsl    %esi, PM_ACTIVE(%ebx)           /* set new */
  198         jmp     sw1
  199 
  200 sw0:
  201         SETOP   %esi,TD_LOCK(%edi)              /* Switchout td_lock */
  202 sw1:
  203         BLOCK_SPIN(%ecx)
  204         /*
  205          * At this point, we've switched address spaces and are ready
  206          * to load up the rest of the next context.
  207          */
  208         cmpl    $0, PCB_EXT(%edx)               /* has pcb extension? */
  209         je      1f                              /* If not, use the default */
  210         movl    $1, PCPU(PRIVATE_TSS)           /* mark use of private tss */
  211         movl    PCB_EXT(%edx), %edi             /* new tss descriptor */
  212         jmp     2f                              /* Load it up */
  213 
  214 1:      /*
  215          * Use the common default TSS instead of our own.
  216          * Set our stack pointer into the TSS, it's set to just
  217          * below the PCB.  In C, common_tss.tss_esp0 = &pcb - 16;
  218          */
  219         leal    -16(%edx), %ebx                 /* leave space for vm86 */
  220         movl    %ebx, PCPU(COMMON_TSS) + TSS_ESP0
  221 
  222         /*
  223          * Test this CPU's  bit in the bitmap to see if this
  224          * CPU was using a private TSS.
  225          */
  226         cmpl    $0, PCPU(PRIVATE_TSS)           /* Already using the common? */
  227         je      3f                              /* if so, skip reloading */
  228         movl    $0, PCPU(PRIVATE_TSS)
  229         PCPU_ADDR(COMMON_TSSD, %edi)
  230 2:
  231         /* Move correct tss descriptor into GDT slot, then reload tr. */
  232         movl    PCPU(TSS_GDT), %ebx             /* entry in GDT */
  233         movl    0(%edi), %eax
  234         movl    4(%edi), %esi
  235         movl    %eax, 0(%ebx)
  236         movl    %esi, 4(%ebx)
  237         movl    $GPROC0_SEL*8, %esi             /* GSEL(GPROC0_SEL, SEL_KPL) */
  238         ltr     %si
  239 3:
  240 
  241         /* Copy the %fs and %gs selectors into this pcpu gdt */
  242         leal    PCB_FSD(%edx), %esi
  243         movl    PCPU(FSGS_GDT), %edi
  244         movl    0(%esi), %eax           /* %fs selector */
  245         movl    4(%esi), %ebx
  246         movl    %eax, 0(%edi)
  247         movl    %ebx, 4(%edi)
  248         movl    8(%esi), %eax           /* %gs selector, comes straight after */
  249         movl    12(%esi), %ebx
  250         movl    %eax, 8(%edi)
  251         movl    %ebx, 12(%edi)
  252 
  253         /* Restore context. */
  254         movl    PCB_EBX(%edx),%ebx
  255         movl    PCB_ESP(%edx),%esp
  256         movl    PCB_EBP(%edx),%ebp
  257         movl    PCB_ESI(%edx),%esi
  258         movl    PCB_EDI(%edx),%edi
  259         movl    PCB_EIP(%edx),%eax
  260         movl    %eax,(%esp)
  261         pushl   PCB_PSL(%edx)
  262         popfl
  263 
  264         movl    %edx, PCPU(CURPCB)
  265         movl    %ecx, PCPU(CURTHREAD)           /* into next thread */
  266 
  267         /*
  268          * Determine the LDT to use and load it if is the default one and
  269          * that is not the current one.
  270          */
  271         movl    TD_PROC(%ecx),%eax
  272         cmpl    $0,P_MD+MD_LDT(%eax)
  273         jnz     1f
  274         movl    _default_ldt,%eax
  275         cmpl    PCPU(CURRENTLDT),%eax
  276         je      2f
  277         lldt    _default_ldt
  278         movl    %eax,PCPU(CURRENTLDT)
  279         jmp     2f
  280 1:
  281         /* Load the LDT when it is not the default one. */
  282         pushl   %edx                            /* Preserve pointer to pcb. */
  283         addl    $P_MD,%eax                      /* Pointer to mdproc is arg. */
  284         pushl   %eax
  285         /*
  286          * Holding dt_lock prevents context switches, so dt_lock cannot
  287          * be held now and set_user_ldt() will not deadlock acquiring it.
  288          */
  289         call    set_user_ldt
  290         addl    $4,%esp
  291         popl    %edx
  292 2:
  293 
  294         /* This must be done after loading the user LDT. */
  295         .globl  cpu_switch_load_gs
  296 cpu_switch_load_gs:
  297         mov     PCB_GS(%edx),%gs
  298 
  299         pushl   %edx
  300         pushl   PCPU(CURTHREAD)
  301         call    npxswitch
  302         popl    %edx
  303         popl    %edx
  304 
  305         /* Test if debug registers should be restored. */
  306         testl   $PCB_DBREGS,PCB_FLAGS(%edx)
  307         jz      1f
  308 
  309         /*
  310          * Restore debug registers.  The special code for dr7 is to
  311          * preserve the current values of its reserved bits.
  312          */
  313         movl    PCB_DR6(%edx),%eax
  314         movl    %eax,%dr6
  315         movl    PCB_DR3(%edx),%eax
  316         movl    %eax,%dr3
  317         movl    PCB_DR2(%edx),%eax
  318         movl    %eax,%dr2
  319         movl    PCB_DR1(%edx),%eax
  320         movl    %eax,%dr1
  321         movl    PCB_DR0(%edx),%eax
  322         movl    %eax,%dr0
  323         movl    %dr7,%eax
  324         andl    $0x0000fc00,%eax
  325         movl    PCB_DR7(%edx),%ecx
  326         andl    $~0x0000fc00,%ecx
  327         orl     %ecx,%eax
  328         movl    %eax,%dr7
  329 1:
  330         ret
  331 
  332 #ifdef INVARIANTS
  333 badsw1:
  334         pushal
  335         pushl   $sw0_1
  336         call    panic
  337 sw0_1:  .asciz  "cpu_throw: no newthread supplied"
  338 
  339 badsw2:
  340         pushal
  341         pushl   $sw0_2
  342         call    panic
  343 sw0_2:  .asciz  "cpu_switch: no curthread supplied"
  344 
  345 badsw3:
  346         pushal
  347         pushl   $sw0_3
  348         call    panic
  349 sw0_3:  .asciz  "cpu_switch: no newthread supplied"
  350 #endif
  351 END(cpu_switch)
  352 
  353 /*
  354  * savectx(pcb)
  355  * Update pcb, saving current processor state.
  356  */
  357 ENTRY(savectx)
  358         /* Fetch PCB. */
  359         movl    4(%esp),%ecx
  360 
  361         /* Save caller's return address.  Child won't execute this routine. */
  362         movl    (%esp),%eax
  363         movl    %eax,PCB_EIP(%ecx)
  364 
  365         movl    %cr3,%eax
  366         movl    %eax,PCB_CR3(%ecx)
  367 
  368         movl    %ebx,PCB_EBX(%ecx)
  369         movl    %esp,PCB_ESP(%ecx)
  370         movl    %ebp,PCB_EBP(%ecx)
  371         movl    %esi,PCB_ESI(%ecx)
  372         movl    %edi,PCB_EDI(%ecx)
  373         mov     %gs,PCB_GS(%ecx)
  374         pushfl
  375         popl    PCB_PSL(%ecx)
  376 
  377         movl    %cr0,%eax
  378         movl    %eax,PCB_CR0(%ecx)
  379         movl    %cr2,%eax
  380         movl    %eax,PCB_CR2(%ecx)
  381         movl    %cr4,%eax
  382         movl    %eax,PCB_CR4(%ecx)
  383 
  384         movl    %dr0,%eax
  385         movl    %eax,PCB_DR0(%ecx)
  386         movl    %dr1,%eax
  387         movl    %eax,PCB_DR1(%ecx)
  388         movl    %dr2,%eax
  389         movl    %eax,PCB_DR2(%ecx)
  390         movl    %dr3,%eax
  391         movl    %eax,PCB_DR3(%ecx)
  392         movl    %dr6,%eax
  393         movl    %eax,PCB_DR6(%ecx)
  394         movl    %dr7,%eax
  395         movl    %eax,PCB_DR7(%ecx)
  396 
  397         mov     %ds,PCB_DS(%ecx)
  398         mov     %es,PCB_ES(%ecx)
  399         mov     %fs,PCB_FS(%ecx)
  400         mov     %ss,PCB_SS(%ecx)
  401         
  402         sgdt    PCB_GDT(%ecx)
  403         sidt    PCB_IDT(%ecx)
  404         sldt    PCB_LDT(%ecx)
  405         str     PCB_TR(%ecx)
  406 
  407         movl    $1,%eax
  408         ret
  409 END(savectx)
  410 
  411 /*
  412  * resumectx(pcb) __fastcall
  413  * Resuming processor state from pcb.
  414  */
  415 ENTRY(resumectx)
  416         /* Restore GDT. */
  417         lgdt    PCB_GDT(%ecx)
  418 
  419         /* Restore segment registers */
  420         movzwl  PCB_DS(%ecx),%eax
  421         mov     %ax,%ds
  422         movzwl  PCB_ES(%ecx),%eax
  423         mov     %ax,%es
  424         movzwl  PCB_FS(%ecx),%eax
  425         mov     %ax,%fs
  426         movzwl  PCB_GS(%ecx),%eax
  427         movw    %ax,%gs
  428         movzwl  PCB_SS(%ecx),%eax
  429         mov     %ax,%ss
  430 
  431         /* Restore CR2, CR4, CR3 and CR0 */
  432         movl    PCB_CR2(%ecx),%eax
  433         movl    %eax,%cr2
  434         movl    PCB_CR4(%ecx),%eax
  435         movl    %eax,%cr4
  436         movl    PCB_CR3(%ecx),%eax
  437         movl    %eax,%cr3
  438         movl    PCB_CR0(%ecx),%eax
  439         movl    %eax,%cr0
  440         jmp     1f
  441 1:
  442 
  443         /* Restore descriptor tables */
  444         lidt    PCB_IDT(%ecx)
  445         lldt    PCB_LDT(%ecx)
  446 
  447 #define SDT_SYS386TSS   9
  448 #define SDT_SYS386BSY   11
  449         /* Clear "task busy" bit and reload TR */
  450         movl    PCPU(TSS_GDT),%eax
  451         andb    $(~SDT_SYS386BSY | SDT_SYS386TSS),5(%eax)
  452         movzwl  PCB_TR(%ecx),%eax
  453         ltr     %ax
  454 #undef SDT_SYS386TSS
  455 #undef SDT_SYS386BSY
  456 
  457         /* Restore debug registers */
  458         movl    PCB_DR0(%ecx),%eax
  459         movl    %eax,%dr0
  460         movl    PCB_DR1(%ecx),%eax
  461         movl    %eax,%dr1
  462         movl    PCB_DR2(%ecx),%eax
  463         movl    %eax,%dr2
  464         movl    PCB_DR3(%ecx),%eax
  465         movl    %eax,%dr3
  466         movl    PCB_DR6(%ecx),%eax
  467         movl    %eax,%dr6
  468         movl    PCB_DR7(%ecx),%eax
  469         movl    %eax,%dr7
  470 
  471         /* Restore other registers */
  472         movl    PCB_EDI(%ecx),%edi
  473         movl    PCB_ESI(%ecx),%esi
  474         movl    PCB_EBP(%ecx),%ebp
  475         movl    PCB_ESP(%ecx),%esp
  476         movl    PCB_EBX(%ecx),%ebx
  477 
  478         /* reload code selector by turning return into intersegmental return */
  479         pushl   PCB_EIP(%ecx)
  480         movl    $KCSEL,4(%esp)
  481         xorl    %eax,%eax
  482         lret
  483 END(resumectx)

Cache object: 4872b0327cfff1755e58c9a69c3ddfac


[ source navigation ] [ diff markup ] [ identifier search ] [ freetext search ] [ file search ] [ list types ] [ track identifier ]


This page is part of the FreeBSD/Linux Linux Kernel Cross-Reference, and was automatically generated using a modified version of the LXR engine.