The Design and Implementation of the FreeBSD Operating System, Second Edition
Now available: The Design and Implementation of the FreeBSD Operating System (Second Edition)


[ source navigation ] [ diff markup ] [ identifier search ] [ freetext search ] [ file search ] [ list types ] [ track identifier ]

FreeBSD/Linux Kernel Cross Reference
sys/i386/i386/vm86bios.s

Version: -  FREEBSD  -  FREEBSD-12-STABLE  -  FREEBSD-12-0  -  FREEBSD-11-STABLE  -  FREEBSD-11-2  -  FREEBSD-11-1  -  FREEBSD-11-0  -  FREEBSD-10-STABLE  -  FREEBSD-10-4  -  FREEBSD-10-3  -  FREEBSD-10-2  -  FREEBSD-10-1  -  FREEBSD-10-0  -  FREEBSD-9-STABLE  -  FREEBSD-9-3  -  FREEBSD-9-2  -  FREEBSD-9-1  -  FREEBSD-9-0  -  FREEBSD-8-STABLE  -  FREEBSD-8-4  -  FREEBSD-8-3  -  FREEBSD-8-2  -  FREEBSD-8-1  -  FREEBSD-8-0  -  FREEBSD-7-STABLE  -  FREEBSD-7-4  -  FREEBSD-7-3  -  FREEBSD-7-2  -  FREEBSD-7-1  -  FREEBSD-7-0  -  FREEBSD-6-STABLE  -  FREEBSD-6-4  -  FREEBSD-6-3  -  FREEBSD-6-2  -  FREEBSD-6-1  -  FREEBSD-6-0  -  FREEBSD-5-STABLE  -  FREEBSD-5-5  -  FREEBSD-5-4  -  FREEBSD-5-3  -  FREEBSD-5-2  -  FREEBSD-5-1  -  FREEBSD-5-0  -  FREEBSD-4-STABLE  -  FREEBSD-3-STABLE  -  FREEBSD22  -  linux-2.6  -  linux-2.4.22  -  MK83  -  MK84  -  PLAN9  -  DFBSD  -  NETBSD  -  NETBSD5  -  NETBSD4  -  NETBSD3  -  NETBSD20  -  OPENBSD  -  xnu-517  -  xnu-792  -  xnu-792.6.70  -  xnu-1228  -  xnu-1456.1.26  -  xnu-1699.24.8  -  xnu-2050.18.24  -  OPENSOLARIS  -  minix-3-1-1 
SearchContext: -  none  -  3  -  10 

    1 /*-
    2  * Copyright (c) 1998 Jonathan Lemon
    3  * All rights reserved.
    4  *
    5  * Redistribution and use in source and binary forms, with or without
    6  * modification, are permitted provided that the following conditions
    7  * are met:
    8  * 1. Redistributions of source code must retain the above copyright
    9  *    notice, this list of conditions and the following disclaimer.
   10  * 2. Redistributions in binary form must reproduce the above copyright
   11  *    notice, this list of conditions and the following disclaimer in the
   12  *    documentation and/or other materials provided with the distribution.
   13  *
   14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
   15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
   16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
   17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
   18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
   19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
   20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
   21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
   22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
   23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
   24  * SUCH DAMAGE.
   25  *
   26  * $FreeBSD: releng/11.1/sys/i386/i386/vm86bios.s 314210 2017-02-24 16:02:01Z kib $
   27  */
   28 
   29 #include <machine/asmacros.h>           /* miscellaneous asm macros */
   30 #include <machine/trap.h>
   31 
   32 #include "assym.s"
   33 
   34 #define SCR_NEWPTD      PCB_ESI         /* readability macros */ 
   35 #define SCR_VMFRAME     PCB_EBP         /* see vm86.c for explanation */
   36 #define SCR_STACK       PCB_ESP
   37 #define SCR_PGTABLE     PCB_EBX
   38 #define SCR_ARGFRAME    PCB_EIP
   39 #define SCR_TSS0        PCB_VM86
   40 #define SCR_TSS1        (PCB_VM86+4)
   41 
   42         .data
   43         ALIGN_DATA
   44 
   45         .globl  vm86pcb
   46 
   47 vm86pcb:                .long   0
   48 
   49         .text
   50 
   51 /*
   52  * vm86_bioscall(struct trapframe_vm86 *vm86)
   53  */
   54 ENTRY(vm86_bioscall)
   55         movl    vm86pcb,%edx            /* scratch data area */
   56         movl    4(%esp),%eax
   57         movl    %eax,SCR_ARGFRAME(%edx) /* save argument pointer */
   58         pushl   %ebx
   59         pushl   %ebp
   60         pushl   %esi
   61         pushl   %edi
   62         pushl   %gs
   63 
   64         pushfl
   65         cli
   66         movl    PCPU(CURTHREAD),%ecx
   67         cmpl    %ecx,PCPU(FPCURTHREAD)  /* do we need to save fp? */
   68         jne     1f
   69         pushl   %edx
   70         movl    TD_PCB(%ecx),%ecx
   71         pushl   PCB_SAVEFPU(%ecx)
   72         call    npxsave
   73         addl    $4,%esp
   74         popl    %edx                    /* recover our pcb */
   75 1:
   76         popfl
   77 
   78         movl    SCR_VMFRAME(%edx),%ebx  /* target frame location */
   79         movl    %ebx,%edi               /* destination */
   80         movl    SCR_ARGFRAME(%edx),%esi /* source (set on entry) */
   81         movl    $VM86_FRAMESIZE/4,%ecx  /* sizeof(struct vm86frame)/4 */
   82         cld
   83         rep
   84         movsl                           /* copy frame to new stack */
   85 
   86         movl    PCPU(CURPCB),%eax
   87         pushl   %eax                    /* save curpcb */
   88         movl    %edx,PCPU(CURPCB)       /* set curpcb to vm86pcb */
   89 
   90         movl    PCPU(TSS_GDT),%ebx      /* entry in GDT */
   91         movl    0(%ebx),%eax
   92         movl    %eax,SCR_TSS0(%edx)     /* save first word */
   93         movl    4(%ebx),%eax
   94         andl    $~0x200, %eax           /* flip 386BSY -> 386TSS */
   95         movl    %eax,SCR_TSS1(%edx)     /* save second word */
   96 
   97         movl    PCB_EXT(%edx),%edi      /* vm86 tssd entry */
   98         movl    0(%edi),%eax
   99         movl    %eax,0(%ebx)
  100         movl    4(%edi),%eax
  101         movl    %eax,4(%ebx)
  102         movl    $GPROC0_SEL*8,%esi      /* GSEL(entry, SEL_KPL) */
  103         ltr     %si
  104 
  105         movl    %cr3,%eax
  106         pushl   %eax                    /* save address space */
  107         movl    IdlePTD,%ecx
  108         movl    %ecx,%ebx
  109         addl    $KERNBASE,%ebx          /* va of Idle PTD */
  110         movl    0(%ebx),%eax
  111         pushl   %eax                    /* old ptde != 0 when booting */
  112         pushl   %ebx                    /* keep for reuse */
  113 
  114         movl    %esp,SCR_STACK(%edx)    /* save current stack location */
  115 
  116         movl    SCR_NEWPTD(%edx),%eax   /* mapping for vm86 page table */
  117         movl    %eax,0(%ebx)            /* ... install as PTD entry 0 */
  118 
  119 #if defined(PAE) || defined(PAE_TABLES)
  120         movl    IdlePDPT,%ecx
  121 #endif
  122         movl    %ecx,%cr3               /* new page tables */
  123         movl    SCR_VMFRAME(%edx),%esp  /* switch to new stack */
  124 
  125         pushl   %esp
  126         call    vm86_prepcall           /* finish setup */
  127         add     $4, %esp
  128         
  129         /*
  130          * Return via doreti
  131          */
  132         MEXITCOUNT
  133         jmp     doreti
  134 
  135 
  136 /*
  137  * vm86_biosret(struct trapframe_vm86 *vm86)
  138  */
  139 ENTRY(vm86_biosret)
  140         movl    vm86pcb,%edx            /* data area */
  141 
  142         movl    4(%esp),%esi            /* source */
  143         movl    SCR_ARGFRAME(%edx),%edi /* destination */
  144         movl    $VM86_FRAMESIZE/4,%ecx  /* size */
  145         cld
  146         rep
  147         movsl                           /* copy frame to original frame */
  148 
  149         movl    SCR_STACK(%edx),%esp    /* back to old stack */
  150         popl    %ebx                    /* saved va of Idle PTD */
  151         popl    %eax
  152         movl    %eax,0(%ebx)            /* restore old pte */
  153         popl    %eax
  154         movl    %eax,%cr3               /* install old page table */
  155 
  156         movl    PCPU(TSS_GDT),%ebx              /* entry in GDT */
  157         movl    SCR_TSS0(%edx),%eax
  158         movl    %eax,0(%ebx)            /* restore first word */
  159         movl    SCR_TSS1(%edx),%eax
  160         movl    %eax,4(%ebx)            /* restore second word */
  161         movl    $GPROC0_SEL*8,%esi      /* GSEL(entry, SEL_KPL) */
  162         ltr     %si
  163         
  164         popl    PCPU(CURPCB)            /* restore curpcb/curproc */
  165         movl    SCR_ARGFRAME(%edx),%edx /* original stack frame */
  166         movl    TF_TRAPNO(%edx),%eax    /* return (trapno) */
  167 
  168         popl    %gs
  169         popl    %edi
  170         popl    %esi
  171         popl    %ebp
  172         popl    %ebx
  173         ret                             /* back to our normal program */

Cache object: eecff993e402b24b511dacfda26d13a6


[ source navigation ] [ diff markup ] [ identifier search ] [ freetext search ] [ file search ] [ list types ] [ track identifier ]


This page is part of the FreeBSD/Linux Linux Kernel Cross-Reference, and was automatically generated using a modified version of the LXR engine.