The Design and Implementation of the FreeBSD Operating System, Second Edition
Now available: The Design and Implementation of the FreeBSD Operating System (Second Edition)


[ source navigation ] [ diff markup ] [ identifier search ] [ freetext search ] [ file search ] [ list types ] [ track identifier ]

FreeBSD/Linux Kernel Cross Reference
sys/i386/i386/vm86bios.s

Version: -  FREEBSD  -  FREEBSD-13-STABLE  -  FREEBSD-13-0  -  FREEBSD-12-STABLE  -  FREEBSD-12-0  -  FREEBSD-11-STABLE  -  FREEBSD-11-0  -  FREEBSD-10-STABLE  -  FREEBSD-10-0  -  FREEBSD-9-STABLE  -  FREEBSD-9-0  -  FREEBSD-8-STABLE  -  FREEBSD-8-0  -  FREEBSD-7-STABLE  -  FREEBSD-7-0  -  FREEBSD-6-STABLE  -  FREEBSD-6-0  -  FREEBSD-5-STABLE  -  FREEBSD-5-0  -  FREEBSD-4-STABLE  -  FREEBSD-3-STABLE  -  FREEBSD22  -  l41  -  OPENBSD  -  linux-2.6  -  MK84  -  PLAN9  -  xnu-8792 
SearchContext: -  none  -  3  -  10 

    1 /*-
    2  * Copyright (c) 1998 Jonathan Lemon
    3  * All rights reserved.
    4  *
    5  * Redistribution and use in source and binary forms, with or without
    6  * modification, are permitted provided that the following conditions
    7  * are met:
    8  * 1. Redistributions of source code must retain the above copyright
    9  *    notice, this list of conditions and the following disclaimer.
   10  * 2. Redistributions in binary form must reproduce the above copyright
   11  *    notice, this list of conditions and the following disclaimer in the
   12  *    documentation and/or other materials provided with the distribution.
   13  *
   14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
   15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
   16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
   17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
   18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
   19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
   20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
   21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
   22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
   23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
   24  * SUCH DAMAGE.
   25  *
   26  * $FreeBSD: releng/9.0/sys/i386/i386/vm86bios.s 217587 2011-01-19 17:09:07Z jkim $
   27  */
   28 
   29 #include "opt_npx.h"
   30 
   31 #include <machine/asmacros.h>           /* miscellaneous asm macros */
   32 #include <machine/trap.h>
   33 
   34 #include "assym.s"
   35 
   36 #define SCR_NEWPTD      PCB_ESI         /* readability macros */ 
   37 #define SCR_VMFRAME     PCB_EBP         /* see vm86.c for explanation */
   38 #define SCR_STACK       PCB_ESP
   39 #define SCR_PGTABLE     PCB_EBX
   40 #define SCR_ARGFRAME    PCB_EIP
   41 #define SCR_TSS0        PCB_VM86
   42 #define SCR_TSS1        (PCB_VM86+4)
   43 
   44         .data
   45         ALIGN_DATA
   46 
   47         .globl  vm86pcb
   48 
   49 vm86pcb:                .long   0
   50 
   51         .text
   52 
   53 /*
   54  * vm86_bioscall(struct trapframe_vm86 *vm86)
   55  */
   56 ENTRY(vm86_bioscall)
   57         movl    vm86pcb,%edx            /* scratch data area */
   58         movl    4(%esp),%eax
   59         movl    %eax,SCR_ARGFRAME(%edx) /* save argument pointer */
   60         pushl   %ebx
   61         pushl   %ebp
   62         pushl   %esi
   63         pushl   %edi
   64         pushl   %gs
   65 
   66 #ifdef DEV_NPX
   67         pushfl
   68         cli
   69         movl    PCPU(CURTHREAD),%ecx
   70         cmpl    %ecx,PCPU(FPCURTHREAD)  /* do we need to save fp? */
   71         jne     1f
   72         testl   %ecx,%ecx
   73         je      1f                      /* no curproc/npxproc */
   74         pushl   %edx
   75         movl    TD_PCB(%ecx),%ecx
   76         pushl   PCB_SAVEFPU(%ecx)
   77         call    npxsave
   78         addl    $4,%esp
   79         popl    %edx                    /* recover our pcb */
   80 1:
   81         popfl
   82 #endif
   83 
   84         movl    SCR_VMFRAME(%edx),%ebx  /* target frame location */
   85         movl    %ebx,%edi               /* destination */
   86         movl    SCR_ARGFRAME(%edx),%esi /* source (set on entry) */
   87         movl    $VM86_FRAMESIZE/4,%ecx  /* sizeof(struct vm86frame)/4 */
   88         cld
   89         rep
   90         movsl                           /* copy frame to new stack */
   91 
   92         movl    PCPU(CURPCB),%eax
   93         pushl   %eax                    /* save curpcb */
   94         movl    %edx,PCPU(CURPCB)       /* set curpcb to vm86pcb */
   95 
   96         movl    PCPU(TSS_GDT),%ebx      /* entry in GDT */
   97         movl    0(%ebx),%eax
   98         movl    %eax,SCR_TSS0(%edx)     /* save first word */
   99         movl    4(%ebx),%eax
  100         andl    $~0x200, %eax           /* flip 386BSY -> 386TSS */
  101         movl    %eax,SCR_TSS1(%edx)     /* save second word */
  102 
  103         movl    PCB_EXT(%edx),%edi      /* vm86 tssd entry */
  104         movl    0(%edi),%eax
  105         movl    %eax,0(%ebx)
  106         movl    4(%edi),%eax
  107         movl    %eax,4(%ebx)
  108         movl    $GPROC0_SEL*8,%esi      /* GSEL(entry, SEL_KPL) */
  109         ltr     %si
  110 
  111         movl    %cr3,%eax
  112         pushl   %eax                    /* save address space */
  113         movl    IdlePTD,%ecx
  114         movl    %ecx,%ebx
  115         addl    $KERNBASE,%ebx          /* va of Idle PTD */
  116         movl    0(%ebx),%eax
  117         pushl   %eax                    /* old ptde != 0 when booting */
  118         pushl   %ebx                    /* keep for reuse */
  119 
  120         movl    %esp,SCR_STACK(%edx)    /* save current stack location */
  121 
  122         movl    SCR_NEWPTD(%edx),%eax   /* mapping for vm86 page table */
  123         movl    %eax,0(%ebx)            /* ... install as PTD entry 0 */
  124 
  125 #ifdef PAE
  126         movl    IdlePDPT,%ecx
  127 #endif
  128         movl    %ecx,%cr3               /* new page tables */
  129         movl    SCR_VMFRAME(%edx),%esp  /* switch to new stack */
  130 
  131         pushl   %esp
  132         call    vm86_prepcall           /* finish setup */
  133         add     $4, %esp
  134         
  135         /*
  136          * Return via doreti
  137          */
  138         MEXITCOUNT
  139         jmp     doreti
  140 
  141 
  142 /*
  143  * vm86_biosret(struct trapframe_vm86 *vm86)
  144  */
  145 ENTRY(vm86_biosret)
  146         movl    vm86pcb,%edx            /* data area */
  147 
  148         movl    4(%esp),%esi            /* source */
  149         movl    SCR_ARGFRAME(%edx),%edi /* destination */
  150         movl    $VM86_FRAMESIZE/4,%ecx  /* size */
  151         cld
  152         rep
  153         movsl                           /* copy frame to original frame */
  154 
  155         movl    SCR_STACK(%edx),%esp    /* back to old stack */
  156         popl    %ebx                    /* saved va of Idle PTD */
  157         popl    %eax
  158         movl    %eax,0(%ebx)            /* restore old pte */
  159         popl    %eax
  160         movl    %eax,%cr3               /* install old page table */
  161 
  162         movl    PCPU(TSS_GDT),%ebx              /* entry in GDT */
  163         movl    SCR_TSS0(%edx),%eax
  164         movl    %eax,0(%ebx)            /* restore first word */
  165         movl    SCR_TSS1(%edx),%eax
  166         movl    %eax,4(%ebx)            /* restore second word */
  167         movl    $GPROC0_SEL*8,%esi      /* GSEL(entry, SEL_KPL) */
  168         ltr     %si
  169         
  170         popl    PCPU(CURPCB)            /* restore curpcb/curproc */
  171         movl    SCR_ARGFRAME(%edx),%edx /* original stack frame */
  172         movl    TF_TRAPNO(%edx),%eax    /* return (trapno) */
  173 
  174         popl    %gs
  175         popl    %edi
  176         popl    %esi
  177         popl    %ebp
  178         popl    %ebx
  179         ret                             /* back to our normal program */

Cache object: 831c711718543f78a6edb96609f04ebc


[ source navigation ] [ diff markup ] [ identifier search ] [ freetext search ] [ file search ] [ list types ] [ track identifier ]


This page is part of the FreeBSD/Linux Linux Kernel Cross-Reference, and was automatically generated using a modified version of the LXR engine.