The Design and Implementation of the FreeBSD Operating System, Second Edition
Now available: The Design and Implementation of the FreeBSD Operating System (Second Edition)


[ source navigation ] [ diff markup ] [ identifier search ] [ freetext search ] [ file search ] [ list types ] [ track identifier ]

FreeBSD/Linux Kernel Cross Reference
sys/powerpc/powerpc/swtch.S

Version: -  FREEBSD  -  FREEBSD-13-STABLE  -  FREEBSD-13-0  -  FREEBSD-12-STABLE  -  FREEBSD-12-0  -  FREEBSD-11-STABLE  -  FREEBSD-11-0  -  FREEBSD-10-STABLE  -  FREEBSD-10-0  -  FREEBSD-9-STABLE  -  FREEBSD-9-0  -  FREEBSD-8-STABLE  -  FREEBSD-8-0  -  FREEBSD-7-STABLE  -  FREEBSD-7-0  -  FREEBSD-6-STABLE  -  FREEBSD-6-0  -  FREEBSD-5-STABLE  -  FREEBSD-5-0  -  FREEBSD-4-STABLE  -  FREEBSD-3-STABLE  -  FREEBSD22  -  l41  -  OPENBSD  -  linux-2.6  -  MK84  -  PLAN9  -  xnu-8792 
SearchContext: -  none  -  3  -  10 

    1 /* $FreeBSD: releng/5.1/sys/powerpc/powerpc/swtch.S 112429 2003-03-20 10:28:20Z grehan $ */
    2 /* $NetBSD: locore.S,v 1.24 2000/05/31 05:09:17 thorpej Exp $ */
    3 
    4 /*
    5  * Copyright (C) 2001 Benno Rice
    6  * All rights reserved.
    7  *
    8  * Redistribution and use in source and binary forms, with or without
    9  * modification, are permitted provided that the following conditions
   10  * are met:
   11  * 1. Redistributions of source code must retain the above copyright
   12  *    notice, this list of conditions and the following disclaimer.
   13  * 2. Redistributions in binary form must reproduce the above copyright
   14  *    notice, this list of conditions and the following disclaimer in the
   15  *    documentation and/or other materials provided with the distribution.
   16  *
   17  * THIS SOFTWARE IS PROVIDED BY Benno Rice ``AS IS'' AND ANY EXPRESS OR
   18  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
   19  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
   20  * IN NO EVENT SHALL TOOLS GMBH BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
   21  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
   22  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
   23  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
   24  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
   25  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
   26  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
   27 */
   28 /*
   29  * Copyright (C) 1995, 1996 Wolfgang Solfrank.
   30  * Copyright (C) 1995, 1996 TooLs GmbH.
   31  * All rights reserved.
   32  *
   33  * Redistribution and use in source and binary forms, with or without
   34  * modification, are permitted provided that the following conditions
   35  * are met:
   36  * 1. Redistributions of source code must retain the above copyright
   37  *    notice, this list of conditions and the following disclaimer.
   38  * 2. Redistributions in binary form must reproduce the above copyright
   39  *    notice, this list of conditions and the following disclaimer in the
   40  *    documentation and/or other materials provided with the distribution.
   41  * 3. All advertising materials mentioning features or use of this software
   42  *    must display the following acknowledgement:
   43  *      This product includes software developed by TooLs GmbH.
   44  * 4. The name of TooLs GmbH may not be used to endorse or promote products
   45  *    derived from this software without specific prior written permission.
   46  *
   47  * THIS SOFTWARE IS PROVIDED BY TOOLS GMBH ``AS IS'' AND ANY EXPRESS OR
   48  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
   49  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
   50  * IN NO EVENT SHALL TOOLS GMBH BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
   51  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
   52  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
   53  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
   54  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
   55  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
   56  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
   57  */
   58 
   59 #include "assym.s"
   60 
   61 #include <sys/syscall.h>
   62 
   63 #include <machine/trap.h>
   64 #include <machine/param.h>
   65 #include <machine/sr.h>
   66 #include <machine/psl.h>
   67 #include <machine/asm.h>
   68 
   69 /*
   70  * void cpu_switch()
   71  * Find a runnable thread and switch to it.
   72  */
   73 ENTRY(cpu_switch)
   74         mfsprg  %r3,0                   /* Get the pcpu pointer */
   75         lwz     %r4,PC_CURTHREAD(%r3)   /* Get the current thread */
   76         lwz     %r3,TD_PCB(%r4)         /* Get a pointer to the PCB */
   77 
   78         mr      %r12,%r2
   79         stmw    %r12,PCB_CONTEXT(%r3)   /* Save the non-volatile GP regs */
   80         mr      %r14,%r3                /* Copy the current pcb pointer */
   81         mr      %r15,%r4                /* ... and the curthread pointer */
   82         mfcr    %r16                    /* Save the condition register */
   83         stw     %r16,PCB_CR(%r3)
   84         mflr    %r16                    /* Save the link register */
   85         stw     %r16,PCB_LR(%r3)
   86         mfsr    %r16,USER_SR            /* Save USER_SR for copyin/out */
   87         isync
   88         stw     %r16,PCB_USR(%r3)
   89         stw     %r1,PCB_SP(%r3)         /* Save the stack pointer */
   90 
   91         lwz     %r5,PCB_FLAGS(%r3)      /* Save FPU context if needed */
   92         andi.   %r5, %r5, PCB_FPU
   93         beq     .L1
   94         mr      %r3,%r15
   95         bl      save_fpu
   96 
   97 .L1:
   98         bl      choosethread            /* Find a new thread to run */
   99         cmplw   0,%r3,%r15              /* Compare to curthread */
  100         beq     .L2                     /* If it's the same, we're done */
  101 
  102         mr      %r16,%r3                /* Save off the (struct thread *) */
  103 
  104         mr      %r3,%r15
  105         bl      pmap_deactivate         /* Deactivate the current pmap */
  106 
  107         mr      %r3,%r16
  108         bl      pmap_activate           /* Activate the new address space */
  109 
  110         mfsprg  %r4,0                   /* Get the pcpu pointer */
  111         stw     %r16,PC_CURTHREAD(%r4)  /* Store new current thread */
  112         mr      %r3,%r16                /*   and save in r3 */
  113         lwz     %r17,TD_PCB(%r16)       /* Store new current PCB */
  114         stw     %r17,PC_CURPCB(%r4)
  115 
  116         lwz     %r5, PCB_FLAGS(%r17)    /* Restore FPU context if needed */
  117         andi.   %r5, %r5, PCB_FPU
  118         beq     .L2
  119         bl      enable_fpu
  120         mr      %r3,%r16                /* Recover new curthread */
  121 
  122         /* thread to restore is in r3 */
  123 .L2:
  124         lwz     %r3, TD_PCB(%r3)
  125         lmw     %r12,PCB_CONTEXT(%r3)   /* Load the non-volatile GP regs */
  126         mr      %r2,%r12
  127         lwz     %r5,PCB_CR(%r3)         /* Load the condition register */
  128         mtcr    %r5
  129         lwz     %r5,PCB_LR(%r3)         /* Load the link register */
  130         mtlr    %r5
  131         lwz     %r5,PCB_USR(%r3)        /* Load the USER_SR segment reg */
  132         mtsr    USER_SR,%r5
  133         isync
  134         lwz     %r1,PCB_SP(%r3)         /* Load the stack pointer */
  135         blr
  136 
  137 /*
  138  * savectx(pcb)
  139  * Update pcb, saving current processor state
  140  */
  141 ENTRY(savectx)
  142         mr      %r12,%r2
  143         stmw    %r12,PCB_CONTEXT(%r3)   /* Save the non-volatile GP regs */
  144         mfcr    %r4                     /* Save the condition register */
  145         stw     %r4,PCB_CONTEXT(%r3)
  146         blr
  147 
  148 /*
  149  * fork_trampoline()
  150  * Set up the return from cpu_fork()
  151  */
  152 ENTRY(fork_trampoline)
  153         lwz     %r3,CF_FUNC(%r1)
  154         lwz     %r4,CF_ARG0(%r1)
  155         lwz     %r5,CF_ARG1(%r1)
  156         bl      fork_exit
  157         addi    %r1,%r1,4
  158         b       trapexit

Cache object: afe6248b0b134fa87d6edb0a52c69ef0


[ source navigation ] [ diff markup ] [ identifier search ] [ freetext search ] [ file search ] [ list types ] [ track identifier ]


This page is part of the FreeBSD/Linux Linux Kernel Cross-Reference, and was automatically generated using a modified version of the LXR engine.