The Design and Implementation of the FreeBSD Operating System, Second Edition
Now available: The Design and Implementation of the FreeBSD Operating System (Second Edition)


[ source navigation ] [ diff markup ] [ identifier search ] [ freetext search ] [ file search ] [ list types ] [ track identifier ]

FreeBSD/Linux Kernel Cross Reference
sys/powerpc/powerpc/swtch.S

Version: -  FREEBSD  -  FREEBSD-13-STABLE  -  FREEBSD-13-0  -  FREEBSD-12-STABLE  -  FREEBSD-12-0  -  FREEBSD-11-STABLE  -  FREEBSD-11-0  -  FREEBSD-10-STABLE  -  FREEBSD-10-0  -  FREEBSD-9-STABLE  -  FREEBSD-9-0  -  FREEBSD-8-STABLE  -  FREEBSD-8-0  -  FREEBSD-7-STABLE  -  FREEBSD-7-0  -  FREEBSD-6-STABLE  -  FREEBSD-6-0  -  FREEBSD-5-STABLE  -  FREEBSD-5-0  -  FREEBSD-4-STABLE  -  FREEBSD-3-STABLE  -  FREEBSD22  -  l41  -  OPENBSD  -  linux-2.6  -  MK84  -  PLAN9  -  xnu-8792 
SearchContext: -  none  -  3  -  10 

    1 /* $FreeBSD$ */
    2 /* $NetBSD: locore.S,v 1.24 2000/05/31 05:09:17 thorpej Exp $ */
    3 
    4 /*-
    5  * Copyright (C) 2001 Benno Rice
    6  * All rights reserved.
    7  *
    8  * Redistribution and use in source and binary forms, with or without
    9  * modification, are permitted provided that the following conditions
   10  * are met:
   11  * 1. Redistributions of source code must retain the above copyright
   12  *    notice, this list of conditions and the following disclaimer.
   13  * 2. Redistributions in binary form must reproduce the above copyright
   14  *    notice, this list of conditions and the following disclaimer in the
   15  *    documentation and/or other materials provided with the distribution.
   16  *
   17  * THIS SOFTWARE IS PROVIDED BY Benno Rice ``AS IS'' AND ANY EXPRESS OR
   18  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
   19  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
   20  * IN NO EVENT SHALL TOOLS GMBH BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
   21  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
   22  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
   23  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
   24  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
   25  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
   26  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
   27 */
   28 /*-
   29  * Copyright (C) 1995, 1996 Wolfgang Solfrank.
   30  * Copyright (C) 1995, 1996 TooLs GmbH.
   31  * All rights reserved.
   32  *
   33  * Redistribution and use in source and binary forms, with or without
   34  * modification, are permitted provided that the following conditions
   35  * are met:
   36  * 1. Redistributions of source code must retain the above copyright
   37  *    notice, this list of conditions and the following disclaimer.
   38  * 2. Redistributions in binary form must reproduce the above copyright
   39  *    notice, this list of conditions and the following disclaimer in the
   40  *    documentation and/or other materials provided with the distribution.
   41  * 3. All advertising materials mentioning features or use of this software
   42  *    must display the following acknowledgement:
   43  *      This product includes software developed by TooLs GmbH.
   44  * 4. The name of TooLs GmbH may not be used to endorse or promote products
   45  *    derived from this software without specific prior written permission.
   46  *
   47  * THIS SOFTWARE IS PROVIDED BY TOOLS GMBH ``AS IS'' AND ANY EXPRESS OR
   48  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
   49  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
   50  * IN NO EVENT SHALL TOOLS GMBH BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
   51  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
   52  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
   53  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
   54  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
   55  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
   56  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
   57  */
   58 
   59 #include "assym.s"
   60 
   61 #include <sys/syscall.h>
   62 
   63 #include <machine/trap.h>
   64 #include <machine/param.h>
   65 #include <machine/sr.h>
   66 #include <machine/psl.h>
   67 #include <machine/asm.h>
   68 
   69 /*
   70  * void cpu_switch(struct thread *old, struct thread *new)
   71  *
   72  * Switch to a new thread saving the current state in the old thread.
   73  */
   74 ENTRY(cpu_switch)
   75         lwz     %r5,TD_PCB(%r3)         /* Get the old thread's PCB ptr */
   76 
   77         mr      %r12,%r2        
   78         stmw    %r12,PCB_CONTEXT(%r5)   /* Save the non-volatile GP regs.
   79                                            These can now be used for scratch */
   80 
   81         mfcr    %r16                    /* Save the condition register */
   82         stw     %r16,PCB_CR(%r5)
   83         mflr    %r16                    /* Save the link register */
   84         stw     %r16,PCB_LR(%r5)
   85         mfsr    %r16,USER_SR            /* Save USER_SR for copyin/out */
   86         isync
   87         stw     %r16,PCB_USR(%r5)
   88         stw     %r1,PCB_SP(%r5)         /* Save the stack pointer */
   89 
   90         mr      %r14,%r3                /* Copy the old thread ptr... */
   91         mr      %r15,%r4                /* and the new thread ptr in scratch */
   92         
   93         lwz     %r6,PCB_FLAGS(%r5)      /* Save FPU context if needed */
   94         andi.   %r6, %r6, PCB_FPU
   95         beq     .L1
   96         bl      save_fpu
   97 
   98 .L1:
   99         lwz     %r6,PCB_FLAGS(%r5)
  100         /* Save Altivec context if needed */
  101         andi.   %r6, %r6, PCB_VEC
  102         beq     .L2
  103         bl      save_vec
  104         
  105 .L2:
  106         mr      %r3,%r14                /* restore old thread ptr */
  107         bl      pmap_deactivate         /* Deactivate the current pmap */
  108 
  109         mr      %r3,%r15                /* Get new thread ptr */
  110         bl      pmap_activate           /* Activate the new address space */
  111 
  112         mfsprg  %r7,0                   /* Get the pcpu pointer */
  113         stw     %r15,PC_CURTHREAD(%r7)  /* Store new current thread */
  114         lwz     %r17,TD_PCB(%r15)       /* Store new current PCB */
  115         stw     %r17,PC_CURPCB(%r7)
  116 
  117         lwz     %r6, PCB_FLAGS(%r17)    /* Restore FPU context if needed */
  118         andi.   %r6, %r6, PCB_FPU
  119         beq     .L3
  120         mr      %r3,%r15                /* Pass curthread to enable_fpu */
  121         bl      enable_fpu
  122 
  123 .L3:
  124         lwz     %r6, PCB_FLAGS(%r17)
  125         /* Restore Altivec context if needed */
  126         andi.   %r6, %r6, PCB_VEC
  127         beq     .L4
  128         mr      %r3,%r15                /* Pass curthread to enable_vec */
  129         bl      enable_vec
  130 
  131         /* thread to restore is in r3 */
  132 .L4:
  133         mr      %r3,%r17                /* Recover PCB ptr */
  134         lmw     %r12,PCB_CONTEXT(%r3)   /* Load the non-volatile GP regs */
  135         mr      %r2,%r12
  136         lwz     %r5,PCB_CR(%r3)         /* Load the condition register */
  137         mtcr    %r5
  138         lwz     %r5,PCB_LR(%r3)         /* Load the link register */
  139         mtlr    %r5
  140         lwz     %r5,PCB_USR(%r3)        /* Load the USER_SR segment reg */
  141         mtsr    USER_SR,%r5
  142         isync
  143         lwz     %r1,PCB_SP(%r3)         /* Load the stack pointer */
  144         blr
  145 
  146 /*
  147  * savectx(pcb)
  148  * Update pcb, saving current processor state
  149  */
  150 ENTRY(savectx)
  151         mr      %r12,%r2
  152         stmw    %r12,PCB_CONTEXT(%r3)   /* Save the non-volatile GP regs */
  153         mfcr    %r4                     /* Save the condition register */
  154         stw     %r4,PCB_CONTEXT(%r3)
  155         blr
  156 
  157 /*
  158  * fork_trampoline()
  159  * Set up the return from cpu_fork()
  160  */
  161 ENTRY(fork_trampoline)
  162         lwz     %r3,CF_FUNC(%r1)
  163         lwz     %r4,CF_ARG0(%r1)
  164         lwz     %r5,CF_ARG1(%r1)
  165         bl      fork_exit
  166         addi    %r1,%r1,CF_SIZE-FSP     /* Allow 8 bytes in front of
  167                                            trapframe to simulate FRAME_SETUP
  168                                            does when allocating space for
  169                                            a frame pointer/saved LR */
  170         b       trapexit

Cache object: 1a9161c8bce6f3c9c224e3d07909092e


[ source navigation ] [ diff markup ] [ identifier search ] [ freetext search ] [ file search ] [ list types ] [ track identifier ]


This page is part of the FreeBSD/Linux Linux Kernel Cross-Reference, and was automatically generated using a modified version of the LXR engine.