1 /* $FreeBSD: releng/5.0/sys/powerpc/powerpc/swtch.s 105611 2002-10-21 05:27:41Z grehan $ */
2 /* $NetBSD: locore.S,v 1.24 2000/05/31 05:09:17 thorpej Exp $ */
3
4 /*
5 * Copyright (C) 2001 Benno Rice
6 * All rights reserved.
7 *
8 * Redistribution and use in source and binary forms, with or without
9 * modification, are permitted provided that the following conditions
10 * are met:
11 * 1. Redistributions of source code must retain the above copyright
12 * notice, this list of conditions and the following disclaimer.
13 * 2. Redistributions in binary form must reproduce the above copyright
14 * notice, this list of conditions and the following disclaimer in the
15 * documentation and/or other materials provided with the distribution.
16 *
17 * THIS SOFTWARE IS PROVIDED BY Benno Rice ``AS IS'' AND ANY EXPRESS OR
18 * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
19 * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
20 * IN NO EVENT SHALL TOOLS GMBH BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
21 * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
22 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
23 * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
24 * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
25 * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
26 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
27 */
28 /*
29 * Copyright (C) 1995, 1996 Wolfgang Solfrank.
30 * Copyright (C) 1995, 1996 TooLs GmbH.
31 * All rights reserved.
32 *
33 * Redistribution and use in source and binary forms, with or without
34 * modification, are permitted provided that the following conditions
35 * are met:
36 * 1. Redistributions of source code must retain the above copyright
37 * notice, this list of conditions and the following disclaimer.
38 * 2. Redistributions in binary form must reproduce the above copyright
39 * notice, this list of conditions and the following disclaimer in the
40 * documentation and/or other materials provided with the distribution.
41 * 3. All advertising materials mentioning features or use of this software
42 * must display the following acknowledgement:
43 * This product includes software developed by TooLs GmbH.
44 * 4. The name of TooLs GmbH may not be used to endorse or promote products
45 * derived from this software without specific prior written permission.
46 *
47 * THIS SOFTWARE IS PROVIDED BY TOOLS GMBH ``AS IS'' AND ANY EXPRESS OR
48 * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
49 * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
50 * IN NO EVENT SHALL TOOLS GMBH BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
51 * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
52 * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
53 * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
54 * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
55 * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
56 * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
57 */
58
59 #include "assym.s"
60
61 #include <sys/syscall.h>
62
63 #include <machine/trap.h>
64 #include <machine/param.h>
65 #include <machine/sr.h>
66 #include <machine/psl.h>
67 #include <machine/asm.h>
68
69 /*
70 * void cpu_switch()
71 * Find a runnable thread and switch to it.
72 */
73 ENTRY(cpu_switch)
74 mfsprg %r3,0 /* Get the pcpu pointer */
75 lwz %r4,PC_CURTHREAD(%r3) /* Get the current thread */
76 lwz %r3,TD_PCB(%r4) /* Get a pointer to the PCB */
77
78 mr %r12,%r2
79 stmw %r12,PCB_CONTEXT(%r3) /* Save the non-volatile GP regs */
80 mr %r14,%r3 /* Copy the current pcb pointer */
81 mr %r15,%r4 /* ... and the curthread pointer */
82 mfcr %r16 /* Save the condition register */
83 stw %r16,PCB_CR(%r3)
84 mflr %r16 /* Save the link register */
85 stw %r16,PCB_LR(%r3)
86 mfsr %r16,USER_SR /* Save USER_SR for copyin/out */
87 isync
88 stw %r16,PCB_USR(%r3)
89 stw %r1,PCB_SP(%r3) /* Save the stack pointer */
90
91 #if 0
92 lwz %r29,PCB_FLAGS(%r3)
93 andi. %r9, %r29, 1 /* XXX - don't hard code */
94 beq .L1
95 bl save_fpu
96 #endif
97
98 .L1:
99 bl choosethread /* Find a new thread to run */
100 cmplw 0,%r3,%r15 /* Compare to curthread */
101 beq .L2 /* If it's the same, we're done */
102
103 mr %r16,%r3 /* Save off the (struct thread *) */
104
105 mr %r3,%r15
106 bl pmap_deactivate /* Deactivate the current pmap */
107
108 mr %r3,%r16
109 bl pmap_activate /* Activate the new address space */
110
111 mfsprg %r4,0 /* Get the pcpu pointer */
112 stw %r16,PC_CURTHREAD(%r4) /* Store new current thread */
113 mr %r3,%r16 /* and save in r3 */
114 lwz %r16,TD_PCB(%r16) /* Store new current PCB */
115 stw %r16,PC_CURPCB(%r4)
116
117 #if 0
118 lwz %r29, PCB_FLAGS(%r4) /* Restore FPU regs if needed */
119 andi. %r9, %r29, 1
120 beq .L2
121 mr %r3, %r4
122 bl enable_fpu
123 #endif
124
125 /* thread to restore is in r3 */
126 .L2:
127 lwz %r3, TD_PCB(%r3)
128 lmw %r12,PCB_CONTEXT(%r3) /* Load the non-volatile GP regs */
129 mr %r2,%r12
130 lwz %r5,PCB_CR(%r3) /* Load the condition register */
131 mtcr %r5
132 lwz %r5,PCB_LR(%r3) /* Load the link register */
133 mtlr %r5
134 lwz %r5,PCB_USR(%r3) /* Load the USER_SR segment reg */
135 mtsr USER_SR,%r5
136 isync
137 lwz %r1,PCB_SP(%r3) /* Load the stack pointer */
138 blr
139
140 /*
141 * savectx(pcb)
142 * Update pcb, saving current processor state
143 */
144 ENTRY(savectx)
145 mr %r12,%r2
146 stmw %r12,PCB_CONTEXT(%r3) /* Save the non-volatile GP regs */
147 mfcr %r4 /* Save the condition register */
148 stw %r4,PCB_CONTEXT(%r3)
149 blr
150
151 /*
152 * fork_trampoline()
153 * Set up the return from cpu_fork()
154 */
155 ENTRY(fork_trampoline)
156 lwz %r3,CF_FUNC(%r1)
157 lwz %r4,CF_ARG0(%r1)
158 lwz %r5,CF_ARG1(%r1)
159 bl fork_exit
160 addi %r1,%r1,4
161 b trapexit
Cache object: 2f6583d92c0d84a84a6f4ac95cc688bd
|