fw_stub.awk

Version: - FREEBSD - FREEBSD-13-STABLE - FREEBSD-13-0 - FREEBSD-12-STABLE - FREEBSD-12-0 - FREEBSD-11-STABLE - FREEBSD-11-0 - FREEBSD-10-STABLE - FREEBSD-10-0 - FREEBSD-9-STABLE - FREEBSD-9-0 - FREEBSD-8-STABLE - FREEBSD-8-0 - FREEBSD-7-STABLE - FREEBSD-7-0 - FREEBSD-6-STABLE - FREEBSD-6-0 - FREEBSD-5-STABLE - FREEBSD-5-0 - FREEBSD-4-STABLE - FREEBSD-3-STABLE - FREEBSD22 - l41 - OPENBSD - linux-2.6 - MK84 - PLAN9 - xnu-8792
SearchContext: - none - 3 - 10

    1 #!/usr/bin/awk -f
    2 
    3 #-
    4 # Copyright (c) 2006 Max Laier.
    5 # All rights reserved.
    6 #
    7 # Redistribution and use in source and binary forms, with or without
    8 # modification, are permitted provided that the following conditions
    9 # are met:
   10 # 1. Redistributions of source code must retain the above copyright
   11 #    notice, this list of conditions and the following disclaimer.
   12 # 2. Redistributions in binary form must reproduce the above copyright
   13 #    notice, this list of conditions and the following disclaimer in the
   14 #    documentation and/or other materials provided with the distribution.
   15 #
   16 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS `AS IS'' AND
   17 # ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
   18 # IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
   19 # ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
   20 # FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
   21 # DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
   22 # OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
   23 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
   24 # LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
   25 # OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
   26 # SUCH DAMAGE.
   27 #
   28 # $FreeBSD$
   29 
   30 #
   31 # Script to generate module .c file from a list of firmware images
   32 #
   33 
   34 function usage ()
   35 {
   36         print "usage: fw_stub <firmware:name>* [-l name] [-m modname] [-c outfile]";
   37         exit 1;
   38 }
   39 
   40 #   These are just for convenience ...
   41 function printc(s)
   42 {
   43         if (opt_c)
   44                 print s > ctmpfilename;
   45         else
   46                 print s > "/dev/stdout";
   47 }
   48 
   49 BEGIN {
   50 
   51 #
   52 #   Process the command line.
   53 #
   54 
   55 num_files = 0;
   56 
   57 for (i = 1; i < ARGC; i++) {
   58         if (ARGV[i] ~ /^-/) {
   59                 #
   60                 #   awk doesn't have getopt(), so we have to do it ourselves.
   61                 #   This is a bit clumsy, but it works.
   62                 #
   63                 for (j = 2; j <= length(ARGV[i]); j++) {
   64                         o = substr(ARGV[i], j, 1);
   65                         if (o == "c") {
   66                                 if (length(ARGV[i]) > j) {
   67                                         opt_c = substr(ARGV[i], j + 1);
   68                                         break;
   69                                 }
   70                                 else {
   71                                         if (++i < ARGC)
   72                                                 opt_c = ARGV[i];
   73                                         else
   74                                                 usage();
   75                                 }
   76                         } else if (o == "m") {
   77                                 if (length(ARGV[i]) > j) {
   78                                         opt_m = substr(ARGV[i], j + 1);
   79                                         break;
   80                                 }
   81                                 else {
   82                                         if (++i < ARGC)
   83                                                 opt_m = ARGV[i];
   84                                         else
   85                                                 usage();
   86                                 }
   87                         } else if (o == "l") {
   88                                 if (length(ARGV[i]) > j) {
   89                                         opt_l = substr(ARGV[i], j + 1);
   90                                         break;
   91                                 }
   92                                 else {
   93                                         if (++i < ARGC)
   94                                                 opt_l = ARGV[i];
   95                                         else
   96                                                 usage();
   97                                 }
   98                         } else
   99                                 usage();
  100                 }
  101         } else {
  102                 split(ARGV[i], curr, ":");
  103                 filenames[num_files] = curr[1];
  104                 if (length(curr[2]) > 0)
  105                         shortnames[num_files] = curr[2];
  106                 else
  107                         shortnames[num_files] = curr[1];
  108                 if (length(curr[3]) > 0)
  109                         versions[num_files] = int(curr[3]);
  110                 else
  111                         versions[num_files] = 0;
  112                 num_files++;
  113         }
  114 }
  115 
  116 if (!num_files || !opt_m)
  117         usage();
  118 
  119 cfilename = opt_c;
  120 ctmpfilename = cfilename ".tmp";
  121 modname = opt_m;
  122 gsub(/[-\.]/, "_", modname);
  123 
  124 printc("#include <sys/param.h>\
  125 #include <sys/errno.h>\
  126 #include <sys/kernel.h>\
  127 #include <sys/module.h>\
  128 #include <sys/linker.h>\
  129 #include <sys/firmware.h>\
  130 #include <sys/systm.h>\n");
  131 
  132 if (opt_l) {
  133         printc("static long " opt_l "_license_ack = 0;");
  134 }
  135 
  136 for (file_i = 0; file_i < num_files; file_i++) {
  137         symb = filenames[file_i];
  138         # '-', '.' and '/' are converted to '_' by ld/objcopy
  139         gsub(/-|\.|\//, "_", symb);
  140         printc("extern char _binary_" symb "_start[], _binary_" symb "_end[];");
  141 }
  142 
  143 printc("\nstatic int\n"\
  144 modname "_fw_modevent(module_t mod, int type, void *unused)\
  145 {\
  146         const struct firmware *fp, *parent;\
  147         int error;\
  148         switch (type) {\
  149         case MOD_LOAD:\n");
  150 
  151 if (opt_l) {
  152                 printc("\
  153                 TUNABLE_LONG_FETCH(\"legal." opt_l ".license_ack\", &" opt_l "_license_ack);\
  154                 if (!" opt_l "_license_ack) {\
  155                         printf(\"" opt_m ": You need to read the LICENSE file in /usr/share/doc/legal/" opt_l "/.\\n\");\
  156                         printf(\"" opt_m ": If you agree with the license, set legal." opt_l ".license_ack=1 in /boot/loader.conf.\\n\");\
  157                         return(EPERM);\
  158                 }\n");
  159 }
  160 
  161 for (file_i = 0; file_i < num_files; file_i++) {
  162         short = shortnames[file_i];
  163         symb = filenames[file_i];
  164         version = versions[file_i];
  165         # '-', '.' and '/' are converted to '_' by ld/objcopy
  166         gsub(/-|\.|\//, "_", symb);
  167 
  168         reg = "\t\tfp = ";
  169         reg = reg "firmware_register(\"" short "\", _binary_" symb "_start , ";
  170         reg = reg "(size_t)(_binary_" symb "_end - _binary_" symb "_start), ";
  171         reg = reg version ", ";
  172 
  173         if (file_i == 0)
  174                 reg = reg "NULL);";
  175         else
  176                 reg = reg "parent);";
  177 
  178         printc(reg);
  179 
  180         printc("\t\tif (fp == NULL)");
  181         printc("\t\t\tgoto fail_" file_i ";");
  182         if (file_i == 0)
  183                 printc("\t\tparent = fp;");
  184 }
  185 
  186 printc("\t\treturn (0);");
  187 
  188 for (file_i = num_files - 1; file_i > 0; file_i--) {
  189         printc("fail_" file_i ":")
  190         printc("\t\t(void)firmware_unregister(\"" shortnames[file_i - 1] "\");");
  191 }
  192 
  193 printc("\tfail_0:");
  194 printc("\t\treturn (ENXIO);");
  195 
  196 printc("\tcase MOD_UNLOAD:");
  197 
  198 for (file_i = 1; file_i < num_files; file_i++) {
  199         printc("\t\terror = firmware_unregister(\"" shortnames[file_i] "\");");
  200         printc("\t\tif (error)");
  201         printc("\t\t\treturn (error);");
  202 }
  203 
  204 printc("\t\terror = firmware_unregister(\"" shortnames[0] "\");");
  205 
  206 printc("\t\treturn (error);\
  207         }\
  208         return (EINVAL);\
  209 }\
  210 \
  211 static moduledata_t " modname "_fw_mod = {\
  212         \"" modname "_fw\",\
  213         " modname "_fw_modevent,\
  214         0\
  215 };\
  216 DECLARE_MODULE(" modname "_fw, " modname "_fw_mod, SI_SUB_DRIVERS, SI_ORDER_FIRST);\
  217 MODULE_VERSION(" modname "_fw, 1);\
  218 MODULE_DEPEND(" modname "_fw, firmware, 1, 1, 1);\
  219 ");
  220 
  221 if (opt_c)
  222         if ((rc = system("mv -f " ctmpfilename " " cfilename))) {
  223                 print "'mv -f " ctmpfilename " " cfilename "' failed: " rc \
  224                     > "/dev/stderr";
  225                 exit 1;
  226         }
  227 
  228 exit 0;
  229 
  230 }

Cache object: d7d9462a49e01b9d5d4cc9a00335c446

[ source navigation ] [ diff markup ] [ identifier search ] [ freetext search ] [ file search ] [ list types ] [ track identifier ]

This page is part of the FreeBSD/Linux Linux Kernel Cross-Reference, and was automatically generated using a modified version of the LXR engine.

FreeBSD/Linux Kernel Cross Reference sys/tools/fw_stub.awk

FreeBSD/Linux Kernel Cross Reference
sys/tools/fw_stub.awk