vnode_if.awk

Version: - FREEBSD - FREEBSD-12-STABLE - FREEBSD-12-0 - FREEBSD-11-STABLE - FREEBSD-11-2 - FREEBSD-11-1 - FREEBSD-11-0 - FREEBSD-10-STABLE - FREEBSD-10-4 - FREEBSD-10-3 - FREEBSD-10-2 - FREEBSD-10-1 - FREEBSD-10-0 - FREEBSD-9-STABLE - FREEBSD-9-3 - FREEBSD-9-2 - FREEBSD-9-1 - FREEBSD-9-0 - FREEBSD-8-STABLE - FREEBSD-8-4 - FREEBSD-8-3 - FREEBSD-8-2 - FREEBSD-8-1 - FREEBSD-8-0 - FREEBSD-7-STABLE - FREEBSD-7-4 - FREEBSD-7-3 - FREEBSD-7-2 - FREEBSD-7-1 - FREEBSD-7-0 - FREEBSD-6-STABLE - FREEBSD-6-4 - FREEBSD-6-3 - FREEBSD-6-2 - FREEBSD-6-1 - FREEBSD-6-0 - FREEBSD-5-STABLE - FREEBSD-5-5 - FREEBSD-5-4 - FREEBSD-5-3 - FREEBSD-5-2 - FREEBSD-5-1 - FREEBSD-5-0 - FREEBSD-4-STABLE - FREEBSD-3-STABLE - FREEBSD22 - linux-2.6 - linux-2.4.22 - MK83 - MK84 - PLAN9 - DFBSD - NETBSD - NETBSD5 - NETBSD4 - NETBSD3 - NETBSD20 - OPENBSD - xnu-517 - xnu-792 - xnu-792.6.70 - xnu-1228 - xnu-1456.1.26 - xnu-1699.24.8 - xnu-2050.18.24 - OPENSOLARIS - minix-3-1-1
SearchContext: - none - 3 - 10
    1 #!/usr/bin/awk -f
    2 
    3 #-
    4 # SPDX-License-Identifier: BSD-3-Clause
    5 #
    6 # Copyright (c) 1992, 1993
    7 #       The Regents of the University of California.  All rights reserved.
    8 #
    9 # Redistribution and use in source and binary forms, with or without
   10 # modification, are permitted provided that the following conditions
   11 # are met:
   12 # 1. Redistributions of source code must retain the above copyright
   13 #    notice, this list of conditions and the following disclaimer.
   14 # 2. Redistributions in binary form must reproduce the above copyright
   15 #    notice, this list of conditions and the following disclaimer in the
   16 #    documentation and/or other materials provided with the distribution.
   17 # 3. Neither the name of the University nor the names of its contributors
   18 #    may be used to endorse or promote products derived from this software
   19 #    without specific prior written permission.
   20 #
   21 # THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
   22 # ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
   23 # IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
   24 # ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
   25 # FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
   26 # DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
   27 # OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
   28 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
   29 # LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
   30 # OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
   31 # SUCH DAMAGE.
   32 
   33 #
   34 #       @(#)vnode_if.sh 8.1 (Berkeley) 6/10/93
   35 # $FreeBSD: head/sys/tools/vnode_if.awk 339672 2018-10-23 21:43:41Z kib $
   36 #
   37 # Script to produce VFS front-end sugar.
   38 #
   39 # usage: vnode_if.awk <srcfile> [-c | -h | -p | -q]
   40 #       (where <srcfile> is currently /sys/kern/vnode_if.src)
   41 #       The source file must have a .src extension
   42 #
   43 
   44 function usage()
   45 {
   46         print "usage: vnode_if.awk <srcfile> [-c|-h|-p|-q]";
   47         exit 1;
   48 }
   49 
   50 function die(msg, what)
   51 {
   52         printf srcfile "(" fnr "): " > "/dev/stderr";
   53         printf msg "\n", what > "/dev/stderr";
   54         exit 1;
   55 }
   56 
   57 function t_spc(type)
   58 {
   59         # Append a space if the type is not a pointer
   60         return (type ~ /\*$/) ? type : type " ";
   61 }
   62 
   63 # These are just for convenience ...
   64 function printc(s) {print s > cfile;}
   65 function printh(s) {print s > hfile;}
   66 function printp(s) {print s > pfile;}
   67 function printq(s) {print s > qfile;}
   68 
   69 function add_debug_code(name, arg, pos, ind)
   70 {
   71         if (arg == "vpp")
   72                 star = "*";
   73         else
   74                 star = "";
   75         if (lockdata[name, arg, pos] && (lockdata[name, arg, pos] != "-")) {
   76                 printc(ind"ASSERT_VI_UNLOCKED("star"a->a_"arg", \""uname"\");");
   77                 # Add assertions for locking
   78                 if (lockdata[name, arg, pos] == "L")
   79                         printc(ind"ASSERT_VOP_LOCKED(" star "a->a_"arg", \""uname"\");");
   80                 else if (lockdata[name, arg, pos] == "U")
   81                         printc(ind"ASSERT_VOP_UNLOCKED(" star "a->a_"arg", \""uname"\");");
   82                 else if (lockdata[name, arg, pos] == "E")
   83                         printc(ind"ASSERT_VOP_ELOCKED(" star "a->a_"arg", \""uname"\");");
   84                 else if (0) {
   85                         # XXX More checks!
   86                 }
   87         }
   88 }
   89 
   90 function add_pre(name)
   91 {
   92         if (lockdata[name, "pre"]) {
   93                 printc("\t"lockdata[name, "pre"]"(a);");
   94         }
   95 }
   96 
   97 function add_post(name)
   98 {
   99         if (lockdata[name, "post"]) {
  100                 printc("\t"lockdata[name, "post"]"(a, rc);");
  101         }
  102 }
  103 
  104 function find_arg_with_type (type)
  105 {
  106         for (jj = 0; jj < numargs; jj++) {
  107                 if (types[jj] == type) {
  108                         return "VOPARG_OFFSETOF(struct " \
  109                             name "_args,a_" args[jj] ")";
  110                 }
  111         }
  112 
  113         return "VDESC_NO_OFFSET";
  114 }
  115 
  116 BEGIN{
  117 
  118 # Process the command line
  119 for (i = 1; i < ARGC; i++) {
  120         arg = ARGV[i];
  121         if (arg !~ /^-[chpq]+$/ && arg !~ /\.src$/)
  122                 usage();
  123         if (arg ~ /^-.*c/)
  124                 cfile = "vnode_if.c";
  125         if (arg ~ /^-.*h/)
  126                 hfile = "vnode_if.h";
  127         if (arg ~ /^-.*p/)
  128                 pfile = "vnode_if_newproto.h";
  129         if (arg ~ /^-.*q/)
  130                 qfile = "vnode_if_typedef.h";
  131         if (arg ~ /\.src$/)
  132                 srcfile = arg;
  133 }
  134 ARGC = 1;
  135 
  136 if (!cfile && !hfile && !pfile && !qfile)
  137         exit 0;
  138 
  139 if (!srcfile)
  140         usage();
  141 
  142 common_head = \
  143     "/*\n" \
  144     " * This file is produced automatically.\n" \
  145     " * Do not modify anything in here by hand.\n" \
  146     " *\n" \
  147     " * Created from $FreeBSD: head/sys/tools/vnode_if.awk 339672 2018-10-23 21:43:41Z kib $\n" \
  148     " */\n" \
  149     "\n";
  150 
  151 if (pfile) {
  152         printp(common_head)
  153         printp("struct vop_vector {")
  154         printp("\tstruct vop_vector\t*vop_default;")
  155         printp("\tvop_bypass_t\t*vop_bypass;")
  156 }
  157 
  158 if (qfile) {
  159         printq(common_head)
  160 }
  161 
  162 if (hfile) {
  163         printh(common_head "extern struct vnodeop_desc vop_default_desc;");
  164         printh("#include \"vnode_if_typedef.h\"")
  165         printh("#include \"vnode_if_newproto.h\"")
  166 }
  167 
  168 if (cfile) {
  169         printc(common_head \
  170             "#include <sys/param.h>\n" \
  171             "#include <sys/event.h>\n" \
  172             "#include <sys/kernel.h>\n" \
  173             "#include <sys/mount.h>\n" \
  174             "#include <sys/sdt.h>\n" \
  175             "#include <sys/signalvar.h>\n" \
  176             "#include <sys/systm.h>\n" \
  177             "#include <sys/vnode.h>\n" \
  178             "\n" \
  179             "SDT_PROVIDER_DECLARE(vfs);\n" \
  180             "\n" \
  181             "struct vnodeop_desc vop_default_desc = {\n" \
  182             "   \"default\",\n" \
  183             "   0,\n" \
  184             "   0,\n" \
  185             "   (vop_bypass_t *)vop_panic,\n" \
  186             "   NULL,\n" \
  187             "   VDESC_NO_OFFSET,\n" \
  188             "   VDESC_NO_OFFSET,\n" \
  189             "   VDESC_NO_OFFSET,\n" \
  190             "   VDESC_NO_OFFSET,\n" \
  191             "};\n");
  192 }
  193 
  194 while ((getline < srcfile) > 0) {
  195         fnr++;
  196         if (NF == 0)
  197                 continue;
  198         if ($1 ~ /^%%/) {
  199                 if (NF != 6 ||
  200                     $2 !~ /^[a-z_]+$/  ||  $3 !~ /^[a-z]+$/  ||
  201                     $4 !~ /^.$/  ||  $5 !~ /^.$/  ||  $6 !~ /^.$/) {
  202                         die("Invalid %s construction", "%%");
  203                         continue;
  204                 }
  205                 lockdata["vop_" $2, $3, "Entry"] = $4;
  206                 lockdata["vop_" $2, $3, "OK"]    = $5;
  207                 lockdata["vop_" $2, $3, "Error"] = $6;                  
  208                 continue;
  209         }
  210 
  211         if ($1 ~ /^%!/) {
  212                 if (NF != 4 ||
  213                     ($3 != "pre" && $3 != "post")) {
  214                         die("Invalid %s construction", "%!");
  215                         continue;
  216                 }
  217                 lockdata["vop_" $2, $3] = $4;
  218                 continue;
  219         }
  220         if ($1 ~ /^#/)
  221                 continue;
  222 
  223         # Get the function name.
  224         name = $1;
  225         uname = toupper(name);
  226 
  227         # Get the function arguments.
  228         for (numargs = 0; ; ++numargs) {
  229                 if ((getline < srcfile) <= 0) {
  230                         die("Unable to read through the arguments for \"%s\"",
  231                             name);
  232                 }
  233                 fnr++;
  234                 if ($1 ~ /^\};/)
  235                         break;
  236 
  237                 # Delete comments, if any.
  238                 gsub (/\/\*.*\*\//, "");
  239 
  240                 # Condense whitespace and delete leading/trailing space.
  241                 gsub(/[[:space:]]+/, " ");
  242                 sub(/^ /, "");
  243                 sub(/ $/, "");
  244 
  245                 # Pick off direction.
  246                 if ($1 != "INOUT" && $1 != "IN" && $1 != "OUT")
  247                         die("No IN/OUT direction for \"%s\".", $0);
  248                 dirs[numargs] = $1;
  249                 sub(/^[A-Z]* /, "");
  250 
  251                 if ((reles[numargs] = $1) == "WILLRELE")
  252                         sub(/^[A-Z]* /, "");
  253                 else
  254                         reles[numargs] = "WONTRELE";
  255 
  256                 # kill trailing ;
  257                 if (sub(/;$/, "") < 1)
  258                         die("Missing end-of-line ; in \"%s\".", $0);
  259 
  260                 # pick off variable name
  261                 if ((argp = match($0, /[A-Za-z0-9_]+$/)) < 1)
  262                         die("Missing var name \"a_foo\" in \"%s\".", $0);
  263                 args[numargs] = substr($0, argp);
  264                 $0 = substr($0, 1, argp - 1);
  265 
  266                 # what is left must be type
  267                 # remove trailing space (if any)
  268                 sub(/ $/, "");
  269                 types[numargs] = $0;
  270         }
  271         if (numargs > 4)
  272                 ctrargs = 4;
  273         else
  274                 ctrargs = numargs;
  275         ctrstr = ctrargs "(KTR_VOP, \"VOP\", \"" uname "\", (uintptr_t)a,\n\t    "; 
  276         ctrstr = ctrstr "\"" args[0] ":0x%jX\", (uintptr_t)a->a_" args[0];
  277         for (i = 1; i < ctrargs; ++i)
  278                 ctrstr = ctrstr ", \"" args[i] ":0x%jX\", a->a_" args[i];
  279         ctrstr = ctrstr ");";
  280 
  281         if (pfile) {
  282                 printp("\t"name"_t\t*"name";")
  283         }
  284         if (qfile) {
  285                 printq("struct "name"_args;")
  286                 printq("typedef int "name"_t(struct "name"_args *);\n")
  287         }
  288 
  289         if (hfile) {
  290                 # Print out the vop_F_args structure.
  291                 printh("struct "name"_args {\n\tstruct vop_generic_args a_gen;");
  292                 for (i = 0; i < numargs; ++i)
  293                         printh("\t" t_spc(types[i]) "a_" args[i] ";");
  294                 printh("};");
  295                 printh("");
  296 
  297                 # Print out extern declaration.
  298                 printh("extern struct vnodeop_desc " name "_desc;");
  299                 printh("");
  300 
  301                 # Print out function prototypes.
  302                 printh("int " uname "_AP(struct " name "_args *);");
  303                 printh("int " uname "_APV(struct vop_vector *vop, struct " name "_args *);");
  304                 printh("");
  305                 printh("static __inline int " uname "(");
  306                 for (i = 0; i < numargs; ++i) {
  307                         printh("\t" t_spc(types[i]) args[i] \
  308                             (i < numargs - 1 ? "," : ")"));
  309                 }
  310                 printh("{");
  311                 printh("\tstruct " name "_args a;");
  312                 printh("");
  313                 printh("\ta.a_gen.a_desc = &" name "_desc;");
  314                 for (i = 0; i < numargs; ++i)
  315                         printh("\ta.a_" args[i] " = " args[i] ";");
  316                 printh("\treturn (" uname "_APV("args[0]"->v_op, &a));");
  317                 printh("}");
  318 
  319                 printh("");
  320         }
  321 
  322         if (cfile) {
  323                 # Print out the vop_F_vp_offsets structure.  This all depends
  324                 # on naming conventions and nothing else.
  325                 printc("static int " name "_vp_offsets[] = {");
  326                 # as a side effect, figure out the releflags
  327                 releflags = "";
  328                 vpnum = 0;
  329                 for (i = 0; i < numargs; i++) {
  330                         if (types[i] == "struct vnode *") {
  331                                 printc("\tVOPARG_OFFSETOF(struct " name \
  332                                     "_args,a_" args[i] "),");
  333                                 if (reles[i] == "WILLRELE") {
  334                                         releflags = releflags \
  335                                             "|VDESC_VP" vpnum "_WILLRELE";
  336                                 }
  337                                 vpnum++;
  338                         }
  339                 }
  340 
  341                 sub(/^\|/, "", releflags);
  342                 printc("\tVDESC_NO_OFFSET");
  343                 printc("};");
  344 
  345                 printc("\n");
  346                 printc("SDT_PROBE_DEFINE2(vfs, vop, " name ", entry, \"struct vnode *\", \"struct " name "_args *\");\n");
  347                 printc("SDT_PROBE_DEFINE3(vfs, vop, " name ", return, \"struct vnode *\", \"struct " name "_args *\", \"int\");\n");
  348 
  349                 # Print out function.
  350                 printc("\nint\n" uname "_AP(struct " name "_args *a)");
  351                 printc("{");
  352                 printc("");
  353                 printc("\treturn(" uname "_APV(a->a_" args[0] "->v_op, a));");
  354                 printc("}");
  355                 printc("\nint\n" uname "_APV(struct vop_vector *vop, struct " name "_args *a)");
  356                 printc("{");
  357                 printc("\tint rc;");
  358                 printc("");
  359                 printc("\tVNASSERT(a->a_gen.a_desc == &" name "_desc, a->a_" args[0]",");
  360                 printc("\t    (\"Wrong a_desc in " name "(%p, %p)\", a->a_" args[0]", a));");
  361                 printc("\twhile(vop != NULL && \\");
  362                 printc("\t    vop->"name" == NULL && vop->vop_bypass == NULL)")
  363                 printc("\t\tvop = vop->vop_default;")
  364                 printc("\tVNASSERT(vop != NULL, a->a_" args[0]", (\"No "name"(%p, %p)\", a->a_" args[0]", a));")
  365                 printc("\tSDT_PROBE2(vfs, vop, " name ", entry, a->a_" args[0] ", a);\n");
  366                 for (i = 0; i < numargs; ++i)
  367                         add_debug_code(name, args[i], "Entry", "\t");
  368                 printc("\tKTR_START" ctrstr);
  369                 add_pre(name);
  370                 printc("\tif (vop->"name" != NULL)")
  371                 printc("\t\trc = vop->"name"(a);")
  372                 printc("\telse")
  373                 printc("\t\trc = vop->vop_bypass(&a->a_gen);")
  374                 printc("\tSDT_PROBE3(vfs, vop, " name ", return, a->a_" args[0] ", a, rc);\n");
  375                 printc("\tif (rc == 0) {");
  376                 for (i = 0; i < numargs; ++i)
  377                         add_debug_code(name, args[i], "OK", "\t\t");
  378                 printc("\t} else {");
  379                 for (i = 0; i < numargs; ++i)
  380                         add_debug_code(name, args[i], "Error", "\t\t");
  381                 printc("\t}");
  382                 add_post(name);
  383                 printc("\tKTR_STOP" ctrstr);
  384                 printc("\treturn (rc);");
  385                 printc("}\n");
  386 
  387                 # Print out the vnodeop_desc structure.
  388                 printc("struct vnodeop_desc " name "_desc = {");
  389                 # printable name
  390                 printc("\t\"" name "\",");
  391                 # flags
  392                 vppwillrele = "";
  393                 for (i = 0; i < numargs; i++) {
  394                         if (types[i] == "struct vnode **" && \
  395                             reles[i] == "WILLRELE") {
  396                                 vppwillrele = "|VDESC_VPP_WILLRELE";
  397                         }
  398                 }
  399 
  400                 if (!releflags)
  401                         releflags = "0";
  402                 printc("\t" releflags vppwillrele ",");
  403 
  404                 # index in struct vop_vector
  405                 printc("\t__offsetof(struct vop_vector, " name "),");
  406                 # function to call
  407                 printc("\t(vop_bypass_t *)" uname "_AP,");
  408                 # vp offsets
  409                 printc("\t" name "_vp_offsets,");
  410                 # vpp (if any)
  411                 printc("\t" find_arg_with_type("struct vnode **") ",");
  412                 # cred (if any)
  413                 printc("\t" find_arg_with_type("struct ucred *") ",");
  414                 # thread (if any)
  415                 printc("\t" find_arg_with_type("struct thread *") ",");
  416                 # componentname
  417                 printc("\t" find_arg_with_type("struct componentname *") ",");
  418                 # transport layer information
  419                 printc("};\n");
  420         }
  421 }
  422  
  423 if (pfile)
  424         printp("};")
  425  
  426 if (hfile)
  427         close(hfile);
  428 if (cfile)
  429         close(cfile);
  430 if (pfile)
  431         close(pfile);
  432 close(srcfile);
  433 
  434 exit 0;
  435 
  436 }
Cache object: 2c25ec21135d3f7829df14c7163b9e2a
[ source navigation ] [ diff markup ] [ identifier search ] [ freetext search ] [ file search ] [ list types ] [ track identifier ]
This page is part of the FreeBSD/Linux Linux Kernel Cross-Reference, and was automatically generated using a modified version of the LXR engine.
FreeBSD/Linux Kernel Cross Reference sys/tools/vnode_if.awk

FreeBSD/Linux Kernel Cross Reference
sys/tools/vnode_if.awk
