The Design and Implementation of the FreeBSD Operating System, Second Edition
Now available: The Design and Implementation of the FreeBSD Operating System (Second Edition)


[ source navigation ] [ diff markup ] [ identifier search ] [ freetext search ] [ file search ] [ list types ] [ track identifier ]

FreeBSD/Linux Kernel Cross Reference
sys/tools/vnode_if.awk

Version: -  FREEBSD  -  FREEBSD-12-STABLE  -  FREEBSD-12-0  -  FREEBSD-11-STABLE  -  FREEBSD-11-2  -  FREEBSD-11-1  -  FREEBSD-11-0  -  FREEBSD-10-STABLE  -  FREEBSD-10-4  -  FREEBSD-10-3  -  FREEBSD-10-2  -  FREEBSD-10-1  -  FREEBSD-10-0  -  FREEBSD-9-STABLE  -  FREEBSD-9-3  -  FREEBSD-9-2  -  FREEBSD-9-1  -  FREEBSD-9-0  -  FREEBSD-8-STABLE  -  FREEBSD-8-4  -  FREEBSD-8-3  -  FREEBSD-8-2  -  FREEBSD-8-1  -  FREEBSD-8-0  -  FREEBSD-7-STABLE  -  FREEBSD-7-4  -  FREEBSD-7-3  -  FREEBSD-7-2  -  FREEBSD-7-1  -  FREEBSD-7-0  -  FREEBSD-6-STABLE  -  FREEBSD-6-4  -  FREEBSD-6-3  -  FREEBSD-6-2  -  FREEBSD-6-1  -  FREEBSD-6-0  -  FREEBSD-5-STABLE  -  FREEBSD-5-5  -  FREEBSD-5-4  -  FREEBSD-5-3  -  FREEBSD-5-2  -  FREEBSD-5-1  -  FREEBSD-5-0  -  FREEBSD-4-STABLE  -  FREEBSD-3-STABLE  -  FREEBSD22  -  linux-2.6  -  linux-2.4.22  -  MK83  -  MK84  -  PLAN9  -  DFBSD  -  NETBSD  -  NETBSD5  -  NETBSD4  -  NETBSD3  -  NETBSD20  -  OPENBSD  -  xnu-517  -  xnu-792  -  xnu-792.6.70  -  xnu-1228  -  xnu-1456.1.26  -  xnu-1699.24.8  -  xnu-2050.18.24  -  OPENSOLARIS  -  minix-3-1-1 
SearchContext: -  none  -  3  -  10 

    1 #!/usr/bin/awk -f
    2 
    3 #-
    4 # Copyright (c) 1992, 1993
    5 #       The Regents of the University of California.  All rights reserved.
    6 #
    7 # Redistribution and use in source and binary forms, with or without
    8 # modification, are permitted provided that the following conditions
    9 # are met:
   10 # 1. Redistributions of source code must retain the above copyright
   11 #    notice, this list of conditions and the following disclaimer.
   12 # 2. Redistributions in binary form must reproduce the above copyright
   13 #    notice, this list of conditions and the following disclaimer in the
   14 #    documentation and/or other materials provided with the distribution.
   15 # 4. Neither the name of the University nor the names of its contributors
   16 #    may be used to endorse or promote products derived from this software
   17 #    without specific prior written permission.
   18 #
   19 # THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
   20 # ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
   21 # IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
   22 # ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
   23 # FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
   24 # DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
   25 # OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
   26 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
   27 # LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
   28 # OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
   29 # SUCH DAMAGE.
   30 
   31 #
   32 #       @(#)vnode_if.sh 8.1 (Berkeley) 6/10/93
   33 # $FreeBSD: releng/6.4/sys/tools/vnode_if.awk 147198 2005-06-09 20:20:31Z ssouhlal $
   34 #
   35 # Script to produce VFS front-end sugar.
   36 #
   37 # usage: vnode_if.awk <srcfile> [-c | -h]
   38 #       (where <srcfile> is currently /sys/kern/vnode_if.src)
   39 #
   40 
   41 function usage()
   42 {
   43         print "usage: vnode_if.awk <srcfile> [-c|-h|-p|-q]";
   44         exit 1;
   45 }
   46 
   47 function die(msg, what)
   48 {
   49         printf msg "\n", what > "/dev/stderr";
   50         exit 1;
   51 }
   52 
   53 function t_spc(type)
   54 {
   55         # Append a space if the type is not a pointer
   56         return (type ~ /\*$/) ? type : type " ";
   57 }
   58 
   59 # These are just for convenience ...
   60 function printc(s) {print s > cfile;}
   61 function printh(s) {print s > hfile;}
   62 function printp(s) {print s > pfile;}
   63 function printq(s) {print s > qfile;}
   64 
   65 function add_debug_code(name, arg, pos, ind)
   66 {
   67         if (arg == "vpp")
   68                 star = "*";
   69         else
   70                 star = "";
   71         if (lockdata[name, arg, pos] && (lockdata[name, arg, pos] != "-")) {
   72                 if (arg ~ /^\*/) {
   73                         printc(ind"if ("substr(arg, 2)" != NULL) {");
   74                 }
   75                 printc(ind"ASSERT_VI_UNLOCKED("star"a->a_"arg", \""uname"\");");
   76                 # Add assertions for locking
   77                 if (lockdata[name, arg, pos] == "L")
   78                         printc(ind"ASSERT_VOP_LOCKED(" star "a->a_"arg", \""uname"\");");
   79                 else if (lockdata[name, arg, pos] == "U")
   80                         printc(ind"ASSERT_VOP_UNLOCKED(" star "a->a_"arg", \""uname"\");");
   81                 else if (lockdata[name, arg, pos] == "E")
   82                         printc(ind"ASSERT_VOP_ELOCKED(" star "a->a_"arg", \""uname"\");");
   83                 else if (0) {
   84                         # XXX More checks!
   85                 }
   86                 if (arg ~ /^\*/) {
   87                         printc("ind}");
   88                 }
   89         }
   90 }
   91 
   92 function add_pre(name)
   93 {
   94         if (lockdata[name, "pre"]) {
   95                 printc("\t"lockdata[name, "pre"]"(a);");
   96         }
   97 }
   98 
   99 function add_post(name)
  100 {
  101         if (lockdata[name, "post"]) {
  102                 printc("\t"lockdata[name, "post"]"(a, rc);");
  103         }
  104 }
  105 
  106 function find_arg_with_type (type)
  107 {
  108         for (jj = 0; jj < numargs; jj++) {
  109                 if (types[jj] == type) {
  110                         return "VOPARG_OFFSETOF(struct " \
  111                             name "_args,a_" args[jj] ")";
  112                 }
  113         }
  114 
  115         return "VDESC_NO_OFFSET";
  116 }
  117 
  118 BEGIN{
  119 
  120 # Process the command line
  121 for (i = 1; i < ARGC; i++) {
  122         arg = ARGV[i];
  123         if (arg !~ /^-[chpq]+$/ && arg !~ /\.src$/)
  124                 usage();
  125         if (arg ~ /^-.*c/)
  126                 cfile = "vnode_if.c";
  127         if (arg ~ /^-.*h/)
  128                 hfile = "vnode_if.h";
  129         if (arg ~ /^-.*p/)
  130                 pfile = "vnode_if_newproto.h";
  131         if (arg ~ /^-.*q/)
  132                 qfile = "vnode_if_typedef.h";
  133         if (arg ~ /\.src$/)
  134                 srcfile = arg;
  135 }
  136 ARGC = 1;
  137 
  138 if (!cfile && !hfile && !pfile && !qfile)
  139         exit 0;
  140 
  141 if (!srcfile)
  142         usage();
  143 
  144 common_head = \
  145     "/*\n" \
  146     " * This file is produced automatically.\n" \
  147     " * Do not modify anything in here by hand.\n" \
  148     " *\n" \
  149     " * Created from $FreeBSD: releng/6.4/sys/tools/vnode_if.awk 147198 2005-06-09 20:20:31Z ssouhlal $\n" \
  150     " */\n" \
  151     "\n";
  152 
  153 if (pfile) {
  154         printp(common_head)
  155         printp("struct vop_vector {")
  156         printp("\tstruct vop_vector\t*vop_default;")
  157         printp("\tvop_bypass_t\t*vop_bypass;")
  158 }
  159 
  160 if (qfile) {
  161         printq(common_head)
  162 }
  163 
  164 if (hfile) {
  165         printh(common_head "extern struct vnodeop_desc vop_default_desc;");
  166         printh("#include \"vnode_if_typedef.h\"")
  167         printh("#include \"vnode_if_newproto.h\"")
  168 }
  169 
  170 if (cfile) {
  171         printc(common_head \
  172             "#include <sys/param.h>\n" \
  173             "#include <sys/event.h>\n" \
  174             "#include <sys/mount.h>\n" \
  175             "#include <sys/systm.h>\n" \
  176             "#include <sys/vnode.h>\n" \
  177             "\n" \
  178             "struct vnodeop_desc vop_default_desc = {\n" \
  179             "   \"default\",\n" \
  180             "   0,\n" \
  181             "   (void *)(uintptr_t)vop_panic,\n" \
  182             "   NULL,\n" \
  183             "   VDESC_NO_OFFSET,\n" \
  184             "   VDESC_NO_OFFSET,\n" \
  185             "   VDESC_NO_OFFSET,\n" \
  186             "   VDESC_NO_OFFSET,\n" \
  187             "   NULL,\n" \
  188             "};\n");
  189 }
  190 
  191 while ((getline < srcfile) > 0) {
  192         if (NF == 0)
  193                 continue;
  194         if ($1 ~ /^#%/) {
  195                 if (NF != 6  ||  $1 != "#%"  || \
  196                     $2 !~ /^[a-z]+$/  ||  $3 !~ /^[a-z]+$/  || \
  197                     $4 !~ /^.$/  ||  $5 !~ /^.$/  ||  $6 !~ /^.$/)
  198                         continue;
  199                 lockdata["vop_" $2, $3, "Entry"] = $4;
  200                 lockdata["vop_" $2, $3, "OK"]    = $5;
  201                 lockdata["vop_" $2, $3, "Error"] = $6;                  
  202                 continue;
  203         }
  204 
  205         if ($1 ~ /^#!/) {
  206                 if (NF != 4 || $1 != "#!")
  207                         continue;
  208                 if ($3 != "pre" && $3 != "post")
  209                         continue;
  210                 lockdata["vop_" $2, $3] = $4;
  211                 continue;
  212         }
  213         if ($1 ~ /^#/)
  214                 continue;
  215 
  216         # Get the function name.
  217         name = $1;
  218         uname = toupper(name);
  219 
  220         # Start constructing a ktrpoint string
  221         ctrstr = "\"" uname;
  222         # Get the function arguments.
  223         for (numargs = 0; ; ++numargs) {
  224                 if ((getline < srcfile) <= 0) {
  225                         die("Unable to read through the arguments for \"%s\"",
  226                             name);
  227                 }
  228                 if ($1 ~ /^\};/)
  229                         break;
  230 
  231                 # Delete comments, if any.
  232                 gsub (/\/\*.*\*\//, "");
  233 
  234                 # Condense whitespace and delete leading/trailing space.
  235                 gsub(/[[:space:]]+/, " ");
  236                 sub(/^ /, "");
  237                 sub(/ $/, "");
  238 
  239                 # Pick off direction.
  240                 if ($1 != "INOUT" && $1 != "IN" && $1 != "OUT")
  241                         die("No IN/OUT direction for \"%s\".", $0);
  242                 dirs[numargs] = $1;
  243                 sub(/^[A-Z]* /, "");
  244 
  245                 if ((reles[numargs] = $1) == "WILLRELE")
  246                         sub(/^[A-Z]* /, "");
  247                 else
  248                         reles[numargs] = "WONTRELE";
  249 
  250                 # kill trailing ;
  251                 if (sub(/;$/, "") < 1)
  252                         die("Missing end-of-line ; in \"%s\".", $0);
  253 
  254                 # pick off variable name
  255                 if ((argp = match($0, /[A-Za-z0-9_]+$/)) < 1)
  256                         die("Missing var name \"a_foo\" in \"%s\".", $0);
  257                 args[numargs] = substr($0, argp);
  258                 $0 = substr($0, 1, argp - 1);
  259 
  260                 # what is left must be type
  261                 # remove trailing space (if any)
  262                 sub(/ $/, "");
  263                 types[numargs] = $0;
  264 
  265                 # We can do a maximum of 6 arguments to CTR*
  266                 if (numargs <= 6) {
  267                         if (numargs == 0)
  268                                 ctrstr = ctrstr "(" args[numargs];
  269                         else
  270                                 ctrstr = ctrstr ", " args[numargs];
  271                         if (types[numargs] ~ /\*/)
  272                                 ctrstr = ctrstr " 0x%lX";
  273                         else
  274                                 ctrstr = ctrstr " %ld";
  275                 }
  276         }
  277         if (numargs > 6)
  278                 ctrargs = 6;
  279         else
  280                 ctrargs = numargs;
  281         ctrstr = "\tCTR" ctrargs "(KTR_VOP,\n\t    " ctrstr ")\",\n\t    ";
  282         ctrstr = ctrstr "a->a_" args[0];
  283         for (i = 1; i < ctrargs; ++i)
  284                 ctrstr = ctrstr ", a->a_" args[i];
  285         ctrstr = ctrstr ");";
  286 
  287         if (pfile) {
  288                 printp("\t"name"_t\t*"name";")
  289         }
  290         if (qfile) {
  291                 printq("struct "name"_args;")
  292                 printq("typedef int "name"_t(struct "name"_args *);\n")
  293         }
  294 
  295         if (hfile) {
  296                 # Print out the vop_F_args structure.
  297                 printh("struct "name"_args {\n\tstruct vop_generic_args a_gen;");
  298                 for (i = 0; i < numargs; ++i)
  299                         printh("\t" t_spc(types[i]) "a_" args[i] ";");
  300                 printh("};");
  301                 printh("");
  302 
  303                 # Print out extern declaration.
  304                 printh("extern struct vnodeop_desc " name "_desc;");
  305                 printh("");
  306 
  307                 # Print out function prototypes.
  308                 printh("int " uname "_AP(struct " name "_args *);");
  309                 printh("int " uname "_APV(struct vop_vector *vop, struct " name "_args *);");
  310                 printh("");
  311                 printh("static __inline int " uname "(");
  312                 for (i = 0; i < numargs; ++i) {
  313                         printh("\t" t_spc(types[i]) args[i] \
  314                             (i < numargs - 1 ? "," : ")"));
  315                 }
  316                 printh("{");
  317                 printh("\tstruct " name "_args a;");
  318                 printh("");
  319                 printh("\ta.a_gen.a_desc = &" name "_desc;");
  320                 for (i = 0; i < numargs; ++i)
  321                         printh("\ta.a_" args[i] " = " args[i] ";");
  322                 printh("\treturn (" uname "_APV("args[0]"->v_op, &a));");
  323                 printh("}");
  324 
  325                 printh("");
  326         }
  327 
  328         if (cfile) {
  329                 # Print out the vop_F_vp_offsets structure.  This all depends
  330                 # on naming conventions and nothing else.
  331                 printc("static int " name "_vp_offsets[] = {");
  332                 # as a side effect, figure out the releflags
  333                 releflags = "";
  334                 vpnum = 0;
  335                 for (i = 0; i < numargs; i++) {
  336                         if (types[i] == "struct vnode *") {
  337                                 printc("\tVOPARG_OFFSETOF(struct " name \
  338                                     "_args,a_" args[i] "),");
  339                                 if (reles[i] == "WILLRELE") {
  340                                         releflags = releflags \
  341                                             "|VDESC_VP" vpnum "_WILLRELE";
  342                                 }
  343                                 vpnum++;
  344                         }
  345                 }
  346 
  347                 sub(/^\|/, "", releflags);
  348                 printc("\tVDESC_NO_OFFSET");
  349                 printc("};");
  350 
  351                 # Print out function.
  352                 printc("\nint\n" uname "_AP(struct " name "_args *a)");
  353                 printc("{");
  354                 printc("");
  355                 printc("\treturn(" uname "_APV(a->a_" args[0] "->v_op, a));");
  356                 printc("}");
  357                 printc("\nint\n" uname "_APV(struct vop_vector *vop, struct " name "_args *a)");
  358                 printc("{");
  359                 printc("\tint rc;");
  360                 printc("");
  361                 printc("\tVNASSERT(a->a_gen.a_desc == &" name "_desc, a->a_" args[0]",");
  362                 printc("\t    (\"Wrong a_desc in " name "(%p, %p)\", a->a_" args[0]", a));");
  363                 printc("\twhile(vop != NULL && \\");
  364                 printc("\t    vop->"name" == NULL && vop->vop_bypass == NULL)")
  365                 printc("\t\tvop = vop->vop_default;")
  366                 printc("\tVNASSERT(vop != NULL, a->a_" args[0]", (\"No "name"(%p, %p)\", a->a_" args[0]", a));")
  367                 for (i = 0; i < numargs; ++i)
  368                         add_debug_code(name, args[i], "Entry", "\t");
  369                 add_pre(name);
  370                 printc("\tif (vop->"name" != NULL)")
  371                 printc("\t\trc = vop->"name"(a);")
  372                 printc("\telse")
  373                 printc("\t\trc = vop->vop_bypass(&a->a_gen);")
  374                 printc(ctrstr);
  375                 printc("\tif (rc == 0) {");
  376                 for (i = 0; i < numargs; ++i)
  377                         add_debug_code(name, args[i], "OK", "\t\t");
  378                 printc("\t} else {");
  379                 for (i = 0; i < numargs; ++i)
  380                         add_debug_code(name, args[i], "Error", "\t\t");
  381                 printc("\t}");
  382                 add_post(name);
  383                 printc("\treturn (rc);");
  384                 printc("}\n");
  385 
  386                 # Print out the vnodeop_desc structure.
  387                 printc("struct vnodeop_desc " name "_desc = {");
  388                 # printable name
  389                 printc("\t\"" name "\",");
  390                 # flags
  391                 vppwillrele = "";
  392                 for (i = 0; i < numargs; i++) {
  393                         if (types[i] == "struct vnode **" && \
  394                             reles[i] == "WILLRELE") {
  395                                 vppwillrele = "|VDESC_VPP_WILLRELE";
  396                         }
  397                 }
  398 
  399                 if (!releflags)
  400                         releflags = "0";
  401                 printc("\t" releflags vppwillrele ",");
  402 
  403                 # function to call
  404                 printc("\t(void*)(uintptr_t)" uname "_AP,");
  405                 # vp offsets
  406                 printc("\t" name "_vp_offsets,");
  407                 # vpp (if any)
  408                 printc("\t" find_arg_with_type("struct vnode **") ",");
  409                 # cred (if any)
  410                 printc("\t" find_arg_with_type("struct ucred *") ",");
  411                 # thread (if any)
  412                 printc("\t" find_arg_with_type("struct thread *") ",");
  413                 # componentname
  414                 printc("\t" find_arg_with_type("struct componentname *") ",");
  415                 # transport layer information
  416                 printc("\tNULL,\n};\n");
  417         }
  418 }
  419  
  420 if (pfile)
  421         printp("};")
  422  
  423 if (hfile)
  424         close(hfile);
  425 if (cfile)
  426         close(cfile);
  427 if (pfile)
  428         close(pfile);
  429 close(srcfile);
  430 
  431 exit 0;
  432 
  433 }

Cache object: 36eb021a3cbaa543e1b806ade9ad4c99


[ source navigation ] [ diff markup ] [ identifier search ] [ freetext search ] [ file search ] [ list types ] [ track identifier ]


This page is part of the FreeBSD/Linux Linux Kernel Cross-Reference, and was automatically generated using a modified version of the LXR engine.