The Design and Implementation of the FreeBSD Operating System, Second Edition
Now available: The Design and Implementation of the FreeBSD Operating System (Second Edition)


[ source navigation ] [ diff markup ] [ identifier search ] [ freetext search ] [ file search ] [ list types ] [ track identifier ]

FreeBSD/Linux Kernel Cross Reference
sys/tools/vnode_if.awk

Version: -  FREEBSD  -  FREEBSD-12-STABLE  -  FREEBSD-12-0  -  FREEBSD-11-STABLE  -  FREEBSD-11-2  -  FREEBSD-11-1  -  FREEBSD-11-0  -  FREEBSD-10-STABLE  -  FREEBSD-10-4  -  FREEBSD-10-3  -  FREEBSD-10-2  -  FREEBSD-10-1  -  FREEBSD-10-0  -  FREEBSD-9-STABLE  -  FREEBSD-9-3  -  FREEBSD-9-2  -  FREEBSD-9-1  -  FREEBSD-9-0  -  FREEBSD-8-STABLE  -  FREEBSD-8-4  -  FREEBSD-8-3  -  FREEBSD-8-2  -  FREEBSD-8-1  -  FREEBSD-8-0  -  FREEBSD-7-STABLE  -  FREEBSD-7-4  -  FREEBSD-7-3  -  FREEBSD-7-2  -  FREEBSD-7-1  -  FREEBSD-7-0  -  FREEBSD-6-STABLE  -  FREEBSD-6-4  -  FREEBSD-6-3  -  FREEBSD-6-2  -  FREEBSD-6-1  -  FREEBSD-6-0  -  FREEBSD-5-STABLE  -  FREEBSD-5-5  -  FREEBSD-5-4  -  FREEBSD-5-3  -  FREEBSD-5-2  -  FREEBSD-5-1  -  FREEBSD-5-0  -  FREEBSD-4-STABLE  -  FREEBSD-3-STABLE  -  FREEBSD22  -  linux-2.6  -  linux-2.4.22  -  MK83  -  MK84  -  PLAN9  -  DFBSD  -  NETBSD  -  NETBSD5  -  NETBSD4  -  NETBSD3  -  NETBSD20  -  OPENBSD  -  xnu-517  -  xnu-792  -  xnu-792.6.70  -  xnu-1228  -  xnu-1456.1.26  -  xnu-1699.24.8  -  xnu-2050.18.24  -  OPENSOLARIS  -  minix-3-1-1 
SearchContext: -  none  -  3  -  10 

    1 #!/usr/bin/awk -f
    2 
    3 #-
    4 # Copyright (c) 1992, 1993
    5 #       The Regents of the University of California.  All rights reserved.
    6 #
    7 # Redistribution and use in source and binary forms, with or without
    8 # modification, are permitted provided that the following conditions
    9 # are met:
   10 # 1. Redistributions of source code must retain the above copyright
   11 #    notice, this list of conditions and the following disclaimer.
   12 # 2. Redistributions in binary form must reproduce the above copyright
   13 #    notice, this list of conditions and the following disclaimer in the
   14 #    documentation and/or other materials provided with the distribution.
   15 # 4. Neither the name of the University nor the names of its contributors
   16 #    may be used to endorse or promote products derived from this software
   17 #    without specific prior written permission.
   18 #
   19 # THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
   20 # ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
   21 # IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
   22 # ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
   23 # FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
   24 # DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
   25 # OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
   26 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
   27 # LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
   28 # OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
   29 # SUCH DAMAGE.
   30 
   31 #
   32 #       @(#)vnode_if.sh 8.1 (Berkeley) 6/10/93
   33 # $FreeBSD: releng/8.3/sys/tools/vnode_if.awk 219107 2011-02-28 23:28:35Z rwatson $
   34 #
   35 # Script to produce VFS front-end sugar.
   36 #
   37 # usage: vnode_if.awk <srcfile> [-c | -h | -p | -q]
   38 #       (where <srcfile> is currently /sys/kern/vnode_if.src)
   39 #       The source file must have a .src extension
   40 #
   41 
   42 function usage()
   43 {
   44         print "usage: vnode_if.awk <srcfile> [-c|-h|-p|-q]";
   45         exit 1;
   46 }
   47 
   48 function die(msg, what)
   49 {
   50         printf srcfile "(" fnr "): " > "/dev/stderr";
   51         printf msg "\n", what > "/dev/stderr";
   52         exit 1;
   53 }
   54 
   55 function t_spc(type)
   56 {
   57         # Append a space if the type is not a pointer
   58         return (type ~ /\*$/) ? type : type " ";
   59 }
   60 
   61 # These are just for convenience ...
   62 function printc(s) {print s > cfile;}
   63 function printh(s) {print s > hfile;}
   64 function printp(s) {print s > pfile;}
   65 function printq(s) {print s > qfile;}
   66 
   67 function add_debug_code(name, arg, pos, ind)
   68 {
   69         if (arg == "vpp")
   70                 star = "*";
   71         else
   72                 star = "";
   73         if (lockdata[name, arg, pos] && (lockdata[name, arg, pos] != "-")) {
   74                 printc(ind"ASSERT_VI_UNLOCKED("star"a->a_"arg", \""uname"\");");
   75                 # Add assertions for locking
   76                 if (lockdata[name, arg, pos] == "L")
   77                         printc(ind"ASSERT_VOP_LOCKED(" star "a->a_"arg", \""uname"\");");
   78                 else if (lockdata[name, arg, pos] == "U")
   79                         printc(ind"ASSERT_VOP_UNLOCKED(" star "a->a_"arg", \""uname"\");");
   80                 else if (lockdata[name, arg, pos] == "E")
   81                         printc(ind"ASSERT_VOP_ELOCKED(" star "a->a_"arg", \""uname"\");");
   82                 else if (0) {
   83                         # XXX More checks!
   84                 }
   85         }
   86 }
   87 
   88 function add_pre(name)
   89 {
   90         if (lockdata[name, "pre"]) {
   91                 printc("\t"lockdata[name, "pre"]"(a);");
   92         }
   93 }
   94 
   95 function add_post(name)
   96 {
   97         if (lockdata[name, "post"]) {
   98                 printc("\t"lockdata[name, "post"]"(a, rc);");
   99         }
  100 }
  101 
  102 function find_arg_with_type (type)
  103 {
  104         for (jj = 0; jj < numargs; jj++) {
  105                 if (types[jj] == type) {
  106                         return "VOPARG_OFFSETOF(struct " \
  107                             name "_args,a_" args[jj] ")";
  108                 }
  109         }
  110 
  111         return "VDESC_NO_OFFSET";
  112 }
  113 
  114 BEGIN{
  115 
  116 # Process the command line
  117 for (i = 1; i < ARGC; i++) {
  118         arg = ARGV[i];
  119         if (arg !~ /^-[chpq]+$/ && arg !~ /\.src$/)
  120                 usage();
  121         if (arg ~ /^-.*c/)
  122                 cfile = "vnode_if.c";
  123         if (arg ~ /^-.*h/)
  124                 hfile = "vnode_if.h";
  125         if (arg ~ /^-.*p/)
  126                 pfile = "vnode_if_newproto.h";
  127         if (arg ~ /^-.*q/)
  128                 qfile = "vnode_if_typedef.h";
  129         if (arg ~ /\.src$/)
  130                 srcfile = arg;
  131 }
  132 ARGC = 1;
  133 
  134 if (!cfile && !hfile && !pfile && !qfile)
  135         exit 0;
  136 
  137 if (!srcfile)
  138         usage();
  139 
  140 common_head = \
  141     "/*\n" \
  142     " * This file is produced automatically.\n" \
  143     " * Do not modify anything in here by hand.\n" \
  144     " *\n" \
  145     " * Created from $FreeBSD: releng/8.3/sys/tools/vnode_if.awk 219107 2011-02-28 23:28:35Z rwatson $\n" \
  146     " */\n" \
  147     "\n";
  148 
  149 if (pfile) {
  150         printp(common_head)
  151         printp("struct vop_vector {")
  152         printp("\tstruct vop_vector\t*vop_default;")
  153         printp("\tvop_bypass_t\t*vop_bypass;")
  154 }
  155 
  156 if (qfile) {
  157         printq(common_head)
  158 }
  159 
  160 if (hfile) {
  161         printh(common_head "extern struct vnodeop_desc vop_default_desc;");
  162         printh("#include \"vnode_if_typedef.h\"")
  163         printh("#include \"vnode_if_newproto.h\"")
  164 }
  165 
  166 if (cfile) {
  167         printc(common_head \
  168             "#include \"opt_kdtrace.h\"\n" \
  169             "\n" \
  170             "#include <sys/param.h>\n" \
  171             "#include <sys/event.h>\n" \
  172             "#include <sys/kernel.h>\n" \
  173             "#include <sys/mount.h>\n" \
  174             "#include <sys/sdt.h>\n" \
  175             "#include <sys/systm.h>\n" \
  176             "#include <sys/vnode.h>\n" \
  177             "\n" \
  178             "SDT_PROVIDER_DECLARE(vfs);\n" \
  179             "\n" \
  180             "struct vnodeop_desc vop_default_desc = {\n" \
  181             "   \"default\",\n" \
  182             "   0,\n" \
  183             "   (vop_bypass_t *)vop_panic,\n" \
  184             "   NULL,\n" \
  185             "   VDESC_NO_OFFSET,\n" \
  186             "   VDESC_NO_OFFSET,\n" \
  187             "   VDESC_NO_OFFSET,\n" \
  188             "   VDESC_NO_OFFSET,\n" \
  189             "};\n");
  190 }
  191 
  192 while ((getline < srcfile) > 0) {
  193         fnr++;
  194         if (NF == 0)
  195                 continue;
  196         if ($1 ~ /^%%/) {
  197                 if (NF != 6 ||
  198                     $2 !~ /^[a-z]+$/  ||  $3 !~ /^[a-z]+$/  ||
  199                     $4 !~ /^.$/  ||  $5 !~ /^.$/  ||  $6 !~ /^.$/) {
  200                         die("Invalid %s construction", "%%");
  201                         continue;
  202                 }
  203                 lockdata["vop_" $2, $3, "Entry"] = $4;
  204                 lockdata["vop_" $2, $3, "OK"]    = $5;
  205                 lockdata["vop_" $2, $3, "Error"] = $6;                  
  206                 continue;
  207         }
  208 
  209         if ($1 ~ /^%!/) {
  210                 if (NF != 4 ||
  211                     ($3 != "pre" && $3 != "post")) {
  212                         die("Invalid %s construction", "%!");
  213                         continue;
  214                 }
  215                 lockdata["vop_" $2, $3] = $4;
  216                 continue;
  217         }
  218         if ($1 ~ /^#/)
  219                 continue;
  220 
  221         # Get the function name.
  222         name = $1;
  223         uname = toupper(name);
  224 
  225         # Start constructing a ktrpoint string
  226         ctrstr = "\"" uname;
  227         # Get the function arguments.
  228         for (numargs = 0; ; ++numargs) {
  229                 if ((getline < srcfile) <= 0) {
  230                         die("Unable to read through the arguments for \"%s\"",
  231                             name);
  232                 }
  233                 fnr++;
  234                 if ($1 ~ /^\};/)
  235                         break;
  236 
  237                 # Delete comments, if any.
  238                 gsub (/\/\*.*\*\//, "");
  239 
  240                 # Condense whitespace and delete leading/trailing space.
  241                 gsub(/[[:space:]]+/, " ");
  242                 sub(/^ /, "");
  243                 sub(/ $/, "");
  244 
  245                 # Pick off direction.
  246                 if ($1 != "INOUT" && $1 != "IN" && $1 != "OUT")
  247                         die("No IN/OUT direction for \"%s\".", $0);
  248                 dirs[numargs] = $1;
  249                 sub(/^[A-Z]* /, "");
  250 
  251                 if ((reles[numargs] = $1) == "WILLRELE")
  252                         sub(/^[A-Z]* /, "");
  253                 else
  254                         reles[numargs] = "WONTRELE";
  255 
  256                 # kill trailing ;
  257                 if (sub(/;$/, "") < 1)
  258                         die("Missing end-of-line ; in \"%s\".", $0);
  259 
  260                 # pick off variable name
  261                 if ((argp = match($0, /[A-Za-z0-9_]+$/)) < 1)
  262                         die("Missing var name \"a_foo\" in \"%s\".", $0);
  263                 args[numargs] = substr($0, argp);
  264                 $0 = substr($0, 1, argp - 1);
  265 
  266                 # what is left must be type
  267                 # remove trailing space (if any)
  268                 sub(/ $/, "");
  269                 types[numargs] = $0;
  270 
  271                 # We can do a maximum of 6 arguments to CTR*
  272                 if (numargs <= 6) {
  273                         if (numargs == 0)
  274                                 ctrstr = ctrstr "(" args[numargs];
  275                         else
  276                                 ctrstr = ctrstr ", " args[numargs];
  277                         if (types[numargs] ~ /\*/)
  278                                 ctrstr = ctrstr " 0x%lX";
  279                         else
  280                                 ctrstr = ctrstr " %ld";
  281                 }
  282         }
  283         if (numargs > 6)
  284                 ctrargs = 6;
  285         else
  286                 ctrargs = numargs;
  287         ctrstr = "\tCTR" ctrargs "(KTR_VOP,\n\t    " ctrstr ")\",\n\t    ";
  288         ctrstr = ctrstr "a->a_" args[0];
  289         for (i = 1; i < ctrargs; ++i)
  290                 ctrstr = ctrstr ", a->a_" args[i];
  291         ctrstr = ctrstr ");";
  292 
  293         if (pfile) {
  294                 printp("\t"name"_t\t*"name";")
  295         }
  296         if (qfile) {
  297                 printq("struct "name"_args;")
  298                 printq("typedef int "name"_t(struct "name"_args *);\n")
  299         }
  300 
  301         if (hfile) {
  302                 # Print out the vop_F_args structure.
  303                 printh("struct "name"_args {\n\tstruct vop_generic_args a_gen;");
  304                 for (i = 0; i < numargs; ++i)
  305                         printh("\t" t_spc(types[i]) "a_" args[i] ";");
  306                 printh("};");
  307                 printh("");
  308 
  309                 # Print out extern declaration.
  310                 printh("extern struct vnodeop_desc " name "_desc;");
  311                 printh("");
  312 
  313                 # Print out function prototypes.
  314                 printh("int " uname "_AP(struct " name "_args *);");
  315                 printh("int " uname "_APV(struct vop_vector *vop, struct " name "_args *);");
  316                 printh("");
  317                 printh("static __inline int " uname "(");
  318                 for (i = 0; i < numargs; ++i) {
  319                         printh("\t" t_spc(types[i]) args[i] \
  320                             (i < numargs - 1 ? "," : ")"));
  321                 }
  322                 printh("{");
  323                 printh("\tstruct " name "_args a;");
  324                 printh("");
  325                 printh("\ta.a_gen.a_desc = &" name "_desc;");
  326                 for (i = 0; i < numargs; ++i)
  327                         printh("\ta.a_" args[i] " = " args[i] ";");
  328                 printh("\treturn (" uname "_APV("args[0]"->v_op, &a));");
  329                 printh("}");
  330 
  331                 printh("");
  332         }
  333 
  334         if (cfile) {
  335                 # Print out the vop_F_vp_offsets structure.  This all depends
  336                 # on naming conventions and nothing else.
  337                 printc("static int " name "_vp_offsets[] = {");
  338                 # as a side effect, figure out the releflags
  339                 releflags = "";
  340                 vpnum = 0;
  341                 for (i = 0; i < numargs; i++) {
  342                         if (types[i] == "struct vnode *") {
  343                                 printc("\tVOPARG_OFFSETOF(struct " name \
  344                                     "_args,a_" args[i] "),");
  345                                 if (reles[i] == "WILLRELE") {
  346                                         releflags = releflags \
  347                                             "|VDESC_VP" vpnum "_WILLRELE";
  348                                 }
  349                                 vpnum++;
  350                         }
  351                 }
  352 
  353                 sub(/^\|/, "", releflags);
  354                 printc("\tVDESC_NO_OFFSET");
  355                 printc("};");
  356 
  357                 printc("\n");
  358                 printc("SDT_PROBE_DEFINE2(vfs, vop, " name ", entry, entry, \"struct vnode *\", \"struct " name "_args *\");\n");
  359                 printc("SDT_PROBE_DEFINE3(vfs, vop, " name ", return, return, \"struct vnode *\", \"struct " name "_args *\", \"int\");\n");
  360 
  361                 # Print out function.
  362                 printc("\nint\n" uname "_AP(struct " name "_args *a)");
  363                 printc("{");
  364                 printc("");
  365                 printc("\treturn(" uname "_APV(a->a_" args[0] "->v_op, a));");
  366                 printc("}");
  367                 printc("\nint\n" uname "_APV(struct vop_vector *vop, struct " name "_args *a)");
  368                 printc("{");
  369                 printc("\tint rc;");
  370                 printc("");
  371                 printc("\tVNASSERT(a->a_gen.a_desc == &" name "_desc, a->a_" args[0]",");
  372                 printc("\t    (\"Wrong a_desc in " name "(%p, %p)\", a->a_" args[0]", a));");
  373                 printc("\twhile(vop != NULL && \\");
  374                 printc("\t    vop->"name" == NULL && vop->vop_bypass == NULL)")
  375                 printc("\t\tvop = vop->vop_default;")
  376                 printc("\tVNASSERT(vop != NULL, a->a_" args[0]", (\"No "name"(%p, %p)\", a->a_" args[0]", a));")
  377                 printc("\tSDT_PROBE(vfs, vop, " name ", entry, a->a_" args[0] ", a, 0, 0, 0);\n");
  378                 for (i = 0; i < numargs; ++i)
  379                         add_debug_code(name, args[i], "Entry", "\t");
  380                 add_pre(name);
  381                 printc("\tif (vop->"name" != NULL)")
  382                 printc("\t\trc = vop->"name"(a);")
  383                 printc("\telse")
  384                 printc("\t\trc = vop->vop_bypass(&a->a_gen);")
  385                 printc(ctrstr);
  386                 printc("\tSDT_PROBE(vfs, vop, " name ", return, a->a_" args[0] ", a, rc, 0, 0);\n");
  387                 printc("\tif (rc == 0) {");
  388                 for (i = 0; i < numargs; ++i)
  389                         add_debug_code(name, args[i], "OK", "\t\t");
  390                 printc("\t} else {");
  391                 for (i = 0; i < numargs; ++i)
  392                         add_debug_code(name, args[i], "Error", "\t\t");
  393                 printc("\t}");
  394                 add_post(name);
  395                 printc("\treturn (rc);");
  396                 printc("}\n");
  397 
  398                 # Print out the vnodeop_desc structure.
  399                 printc("struct vnodeop_desc " name "_desc = {");
  400                 # printable name
  401                 printc("\t\"" name "\",");
  402                 # flags
  403                 vppwillrele = "";
  404                 for (i = 0; i < numargs; i++) {
  405                         if (types[i] == "struct vnode **" && \
  406                             reles[i] == "WILLRELE") {
  407                                 vppwillrele = "|VDESC_VPP_WILLRELE";
  408                         }
  409                 }
  410 
  411                 if (!releflags)
  412                         releflags = "0";
  413                 printc("\t" releflags vppwillrele ",");
  414 
  415                 # function to call
  416                 printc("\t(vop_bypass_t *)" uname "_AP,");
  417                 # vp offsets
  418                 printc("\t" name "_vp_offsets,");
  419                 # vpp (if any)
  420                 printc("\t" find_arg_with_type("struct vnode **") ",");
  421                 # cred (if any)
  422                 printc("\t" find_arg_with_type("struct ucred *") ",");
  423                 # thread (if any)
  424                 printc("\t" find_arg_with_type("struct thread *") ",");
  425                 # componentname
  426                 printc("\t" find_arg_with_type("struct componentname *") ",");
  427                 # transport layer information
  428                 printc("};\n");
  429         }
  430 }
  431  
  432 if (pfile)
  433         printp("};")
  434  
  435 if (hfile)
  436         close(hfile);
  437 if (cfile)
  438         close(cfile);
  439 if (pfile)
  440         close(pfile);
  441 close(srcfile);
  442 
  443 exit 0;
  444 
  445 }

Cache object: 40d20e3080d6b877f41c0bdb30b576e1


[ source navigation ] [ diff markup ] [ identifier search ] [ freetext search ] [ file search ] [ list types ] [ track identifier ]


This page is part of the FreeBSD/Linux Linux Kernel Cross-Reference, and was automatically generated using a modified version of the LXR engine.